User talk:BernardH~commonswiki

Hi. Is it possible to share your povray code for http://commons.wikimedia.org/wiki/File:Alexander_horned_sphere.png with us? Thanks, Guido

Here it is:

global_settings {
  assumed_gamma 1
}

camera {
  location <0,3.35,-3.5>
  right (4/3)*x
  up y
  look_at <0, 1.3, 0>
  angle 40
}

light_source {
  <4.5,8,-8>
  color rgb <1,1,1>
}

#declare r = 0.03;					    // torus minor radius
#declare k = 0.5;					    // scale when incrementing level
#declare theta = 75;					    // angle of torus slice removed
#declare level_max = 6;
#declare p1 = <sin(theta*pi/180/2), 1+cos(theta*pi/180/2), 0>;
#declare p2 = <-sin(theta*pi/180/2), 1+cos(theta*pi/180/2), 0>;

#declare torus_section = union {
  difference {
    torus {
      1, r
      rotate 90*x
      translate y
    }
    prism {
      -1.01*r, 1.01*r, 4
      <0,0>, 
      2*<sin(theta*pi/180/2), cos(theta*pi/180/2)>, 
      2*<-sin(theta*pi/180/2), cos(theta*pi/180/2)>
      <0,0>
      rotate -90*x
      translate y
    }
  }
  sphere {
    p1, r
  }
  sphere {
    p2, r
  }
  finish { ambient 0.1 diffuse 0.6 specular 0.6 roughness 0.05 metallic }
}

#macro recursive_torus(L)
#if (L < 5)
  #local c = rgb (<1,0.15,0>*(5-L) + <1,1,0>*L)/5;
#else
  #local c = rgb <1,1,0>;
#end
#if (L = level_max)
  object {
    torus_section
    pigment { c }
  }
#else
  union {
    object {
      torus_section
      pigment { c }
    }
    object {
      recursive_torus(L+1)
      scale k
      rotate 90*z
      translate p1
    }
    object {
      recursive_torus(L+1)
      scale k
      rotate 90*y
      rotate -90*z
      translate p2
    }
  }
#end
#end

object {
  recursive_torus(0)
  translate r*y
}

plane {
  y, 0
  pigment {rgb <0.2,0.2,0.8>}
  finish { ambient 0.1 diffuse 0.6 }
}

--88.163.238.178 22:25, 1 January 2010 (UTC)

Great. So many thanks. Guido

Your account will be renamed

Hello,

The developer team at Wikimedia is making some changes to how accounts work, as part of our on-going efforts to provide new and better tools for our users like cross-wiki notifications. These changes will mean you have the same account name everywhere. This will let us give you new features that will help you edit and discuss better, and allow more flexible user permissions for tools. One of the side-effects of this is that user accounts will now have to be unique across all 900 Wikimedia wikis. See the announcement for more information.

Unfortunately, your account clashes with another account also called BernardH. To make sure that both of you can use all Wikimedia projects in future, we have reserved the name BernardH~commonswiki that only you will have. If you like it, you don't have to do anything. If you do not like it, you can pick out a different name.

Your account will still work as before, and you will be credited for all your edits made so far, but you will have to use the new account name when you log in.

Sorry for the inconvenience.

Yours,
Keegan Peterzell
Community Liaison, Wikimedia Foundation

20:00, 17 March 2015 (UTC)

Renamed

This account has been renamed as part of single-user login finalisation. If you own this account you can log in using your previous username and password for more information. If you do not like this account's new name, you can choose your own using this form after logging in: Special:GlobalRenameRequest. -- Keegan (WMF) (talk)

02:05, 21 April 2015 (UTC)