Category:Concertina cube, checkered

#version 3.6;
global_settings { assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 conserve_energy}}

#include "SolidFromFaceNormalPoints.inc"
#include "colors.inc"

///////////////////////////// camera and light

#declare Camera_Position = <13.2, 10.5, -45>;
camera{
    location Camera_Position
    right    x*image_width/image_height
    angle    12
    look_at  <0, 0, 0>
}

light_source{ <-400, 500, -300> color White*0.9}
light_source{ <400, 200, 100> color White*0.4}
light_source{ Camera_Position  color rgb<0.9,0.9,1>*0.2}
sky_sphere{ pigment{ White } }


#declare TDarkbrown = texture{ pigment{color srgb<219,179,142>/255} };
#declare TLightbrown = texture{ pigment{color srgb<245,234,223>/255} };
#declare TGray = texture{ pigment{color srgb .5} }


/////////////////////////////////// variables

#declare P = array[26]{ <-2,-2,-2>, <-2,-2,0>, <-2,-1,1>, <-2,0,-2>, <-2,1,-1>, <-2,1,1>, <-1,-2,1>, <-1,-1,2>, <-1,1,-2>, <-1,1,2>, <-1,2,-1>, <-1,2,1>, <0,-2,-2>, <0,2,2>, <1,-2,-1>, <1,-2,1>, <1,-1,-2>, <1,-1,2>, <1,1,-2>, <1,2,-1>, <2,-1,-1>, <2,-1,1>, <2,0,2>, <2,1,-1>, <2,2,0>, <2,2,2> }

#declare Edges = array[42]{array[2]{9, 13}, array[2]{20, 23}, array[2]{17, 22}, array[2]{0, 3}, array[2]{14, 20}, array[2]{20, 21}, array[2]{5, 9}, array[2]{4, 10}, array[2]{22, 25}, array[2]{7, 9}, array[2]{8, 10}, array[2]{0, 1}, array[2]{1, 6}, array[2]{3, 4}, array[2]{12, 16}, array[2]{13, 25}, array[2]{23, 24}, array[2]{18, 23}, array[2]{21, 22}, array[2]{14, 15}, array[2]{2, 5}, array[2]{12, 14}, array[2]{2, 7}, array[2]{6, 15}, array[2]{7, 17}, array[2]{6, 7}, array[2]{15, 21}, array[2]{24, 25}, array[2]{16, 20}, array[2]{11, 13}, array[2]{19, 24}, array[2]{0, 12}, array[2]{10, 11}, array[2]{10, 19}, array[2]{1, 2}, array[2]{16, 18}, array[2]{5, 11}, array[2]{18, 19}, array[2]{4, 5}, array[2]{8, 18}, array[2]{3, 8}, array[2]{15, 17}};

#declare RadEdge = .015;


/////////////////////////////////// cube honeycomb

#declare A = box{<-2,-2,-2>, <-1,-1,-1>}

#declare B = object{A translate 2*x}

#declare A = union{ object{A} object{B} }
#declare B = object{A translate y scale -x}

#declare A = union{ object{A} object{B} }
#declare B = object{A translate 2*y}

#declare A = union{ object{A} object{B} }
#declare B = object{A translate z scale -x}

#declare A = union{ object{A} object{B} }
#declare B = object{A translate 2*z}

#declare DarkCubes = union{ object{A} object{B} }
#declare LightCubes = union{ object{DarkCubes} scale -x }


/////////////////////////////////// CSG polyhedron

#declare FaceOffset = 0.34;
#declare EdgeOffset = 0.34;
#declare PrismThickness = FaceOffset*2 + .1;
#declare FaceNormalPoints = array[12]{<-3/2, 0, 3/2>, <4/3, -4/3, -4/3>, <-4/3, -4/3, 4/3>, <0, 3/2, -3/2>, <-3/2, 3/2, 0>, <-4/3, 4/3, -4/3>, <4/3, -4/3, 4/3>, <4/3, 4/3, -4/3>, <3/2, 0, -3/2>, <-4/3, 4/3, 4/3>, <0, -3/2, 3/2>, <3/2, -3/2, 0>};
#declare WeirdDodecahedron = SolidFromFaceNormalPoints(FaceNormalPoints, 0)  // enlarged rectangle and rhombic faces of the concertina cube, but no hexagons

#declare ConcertinaSolid = union{
	intersection{ object{WeirdDodecahedron} object{DarkCubes} texture{TDarkbrown} }
	intersection{ object{WeirdDodecahedron} object{LightCubes} texture{TLightbrown} }
}


/////////////////////////////////// polyhedron edges

#declare ConcertinaEdges = union{
	#for( Index, 0, dimension_size(P, 1) - 1 )
	    sphere{ P[Index], RadEdge }
	#end

	#for( Index, 0, dimension_size(Edges, 1) - 1 )
	    #local EdgeArray = Edges[Index];
	    cylinder{ P[EdgeArray[0]], P[EdgeArray[1]], RadEdge }
	#end

	texture{TGray}
}


/////////////////////////////////// show

union{
	object{ConcertinaSolid}
	object{ConcertinaEdges no_shadow}
	scale 1.5
	//rotate 45*x rotate 5*y
}