File:Smog-krakow.svg
Original file (SVG file, nominally 600 × 480 pixels, file size: 18 KB)
Captions
Summary[edit]
DescriptionSmog-krakow.svg |
Polski: Wykres średniorocznego stężenia PM10 w Krakowie przy Al. Krasińskiego. English: Annual mean concentration of PM10 in Kraków, at Aleja Krasińskiego. |
Date | |
Source |
od 2007: https://powietrze.gios.gov.pl/pjp/current/station_details/archive/400# |
Author | Tbap |
SVG development InfoField | This plot was created with Gnuplot. This plot uses embedded text that can be easily translated using a text editor. |
Uwagi:
- Aleja Krasińskiego notuje najwyższe stężenia w Krakowie, wykres nie jest więc reprezentatywny dla całego miasta. Wybór tej stacji był podyktowany względami praktycznymi: najprościej było dla niej zgromadzić dane.
- od 2007: na stronie POIS występują luki w szeregach czasowych które mogą wpływać na poprawność danych prezentowanych na wykresie. Średnio brakuje średnich dobowych z 20 dni dla każdego roku. Najwięcej brakuje dla 2009 (73 dni), 2012 (66 dni) i 2007 (31 dni).
- Stężenie w 1972 zostało oszacowane na podstawie wykresu i jest stężeniem podawanym dla Śródmieścia, nie Al. Krasińskiego (stacja pomiarowa powstała chyba na początku lat 90.)
Poprawki, aktualizacje i źródła do brakujących danych mile widziane!
Gnuplot source[edit]
Source code
Gnuplot code
set terminal svg size 1300,1000
set terminal svg enhanced background rgb 'white'
set output 'smog-krakow.svg'
set title "Stężenie PM10 w Krakowie przy Al. Krasińskiego"
xMin = 1971
cutLeft = 1973 # where the gap in the plot starts
gap = 20
xMax = 2022
xMaxVirtual = xMax - 19.5
yMax = 410
set xrange [xMin:xMax - gap + 0.5]
set yrange [0:yMax]
set border 2 + 8
set key outside
set key bot center horizontal invert
# draw broken axis symbol
set arrow 1 from xMin, 0 to cutLeft, 0 nohead
set arrow 2 from cutLeft + 0.5, 0 to xMaxVirtual, 0 nohead
set arrow 3 from xMin, yMax to cutLeft, yMax nohead
set arrow 4 from cutLeft + 0.5, yMax to xMaxVirtual, yMax nohead
set arrow 5 from cutLeft - 0.2, -7 to cutLeft + 0.2, 7 nohead
set arrow 6 from cutLeft + 0.2, -7 to cutLeft + 0.6, 7 nohead
set arrow 7 from cutLeft - 0.2, yMax-7 to cutLeft + 0.2, yMax+7 nohead
set arrow 8 from cutLeft + 0.2, yMax-7 to cutLeft + 0.6, yMax+7 nohead
# fake ticks
set xtics ("1972" 1972, "1995" 1975, "2000" 1980, "2005" 1985, "2010" 1990, "2015" 1995, "2020" 2000)
set ylabel "μg/m³"
set datafile separator ","
# before plotting the data series is mapped so that the gap is removed from the data
plot 'data.csv' using ($1 < cutLeft ? $1 : ($1 > cutLeft ? $1 - gap : 1/0)):2:6 with filledcurves title 'zakres stężeń średniodobowych' fs lc rgb "#CCC", \
'' using ($1 < cutLeft ? $1 : ($1 > cutLeft ? $1 - gap : 1/0)):3:5 with filledcurves title 'zakres stężeń średniomiesięcznych' fs lc rgb "#999", \
'' using ($1 < cutLeft ? $1 : ($1 > cutLeft ? $1 - gap : 1/0)):7 with steps lc rgb "red" title 'poziom dopuszczalny stężenia średniorocznego', \
'' using ($1 < cutLeft ? $1 : ($1 > cutLeft ? $1 - gap : 1/0)):4 with lp lt 1 ps 1.5 pt 0 lw 3 lc rgb "black" title 'stężenie średnioroczne', \
'-' with points ls 1 pt 3 lc rgb "black" title 'rekordowe stężenie średnioroczne dla Śródmieścia'
1972,195
e
Data
year,daily-min,monthly-min,average,monthly-max,daily-max,limit
year,daily-min,monthly-min,average,monthly-max,daily-max,limit
1994,,,79,,,50
1995,,,80,,,50
1996,,,86,,,50
1997,,,77,,,50
1998,,,72,,,50
1999,,,65,,,50
2000,,,48,,,50
2001,,,43,,,50
2002,,,89,,,40
2003,,,80,,,40
2004,,,69,,,40
2005,,,86,,,40
2006,,,96,,,40
2007,20,57,82,130,310,40
2008,17,53,81,125,367,40
2009,18,50,79,123,280,40
2010,10,39,79,144,398,40
2011,13,33,77,132,356,40
2012,9,27,66,147,402,40
2013,17,29,60,101,254,40
2014,16,27,64,125,256,40
2015,14,35,68,115,265,40
2016,13,30,57,109,329,40
2017,6,28,55,146,327,40
2018,11,32,57,96,224,40
2019,11,33,49,80,165,40
2020,5,23,39,73,138,40
2021,13,25,45,75,184,40
2022,10,33,47,66,111,40
Licensing[edit]
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 22:38, 6 January 2023 | 600 × 480 (18 KB) | Tbap (talk | contribs) | +2022 | |
22:07, 5 January 2022 | 600 × 480 (18 KB) | Tbap (talk | contribs) | +2021 | ||
07:47, 18 January 2021 | 600 × 480 (18 KB) | Tbap (talk | contribs) | update 2020 | ||
08:26, 20 January 2020 | 600 × 480 (17 KB) | Tbap (talk | contribs) | + 2019 | ||
20:43, 8 January 2019 | 600 × 480 (17 KB) | Tbap (talk | contribs) | + dane za 2018 | ||
22:40, 25 February 2018 | 600 × 480 (14 KB) | Tbap (talk | contribs) | Minor improvements | ||
21:15, 25 February 2018 | 600 × 480 (14 KB) | Tbap (talk | contribs) | User created page with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
File usage on other wikis
The following other wikis use this file:
- Usage on pl.wikipedia.org
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
Short title | Gnuplot |
---|---|
Image title | Produced by GNUPLOT 5.2 patchlevel 8 |
Width | 600 |
Height | 480 |