File:Pentominos 2x3x10.png

#include "colors.inc"

global_settings { ambient_light rgb <10,10,10> }



camera {
	location <100, 100, 100>
	look_at <2,0,5>
	angle 4
}


#declare radiantvertex = union{
cylinder{0, <0,0,1>, .02 pigment {colour White} }
cylinder{0, <0,1,0>, .02 pigment {colour White} }
cylinder{0, <1,0,0>, .02 pigment {colour White} }
}

#declare cubo = union
{
object{radiantvertex}
object{radiantvertex rotate x*180 translate y+z}
object{radiantvertex rotate y*180 translate x+z}
object{radiantvertex rotate z*180 translate x+y}
box { 0, 1 }
}

#declare TNUM = 12;
#declare OSITY = 5;
#declare TRANSP = .5;

#declare cubestructs = array[TNUM][OSITY]	//Structures (cubes positions)
{
	{x, y, x+y, x+2*y, 2*x+2*y},	//F
	{0*y, y, 2*y, 3*y, 4*y},		//I
	{0*y, x, y, 2*y, 3*y},			//L
	{0*y, y, 2*y, x+2*y, x+3*y},	//N
	{0*y, x, y, x+y, x+2*y},		//P
	{x, x+y, x+2*y, 2*y, 2*x+2*y},	//T
	{0*x, x, 2*x, y, 2*x+y},		//U
	{0*x, x, 2*x, y, 2*y},			//V
	{y, x, y+x, 2*x, 2*y},			//W
	{x, y, x+y, x+2*y, 2*x+y},		//X
	{x, x+y, x+2*y, x+3*y, 2*y},	//Y
	{x, x+y, x+2*y, 2*x, 2*y}		//Z
}

#declare pos_rot = array[TNUM][2]			//Collocations (rotation, translation)
{
	{<90,90,0>,3*z},	//F
	{<90,0,0>,<1,1,4>},	//I
	{<90,180,90>,<2,1,9>},	//L
	{<-90,0,-90>,<0,1,6>},	//N
	{<90,90,0>,z},	//P
	{<90,90,0>,7*z},	//T
	{<180,90,0>,<1,1,9>},	//U
	{<90,0,0>,y-z},	//V
	{<90,180,0>,3*x+5*z},	//W
	{<90,0,0>,6*z},	//X
	{<90,0,0>,<1,1,1>},	//Y
	{<90,0,0>,y}	//Z
}

#declare piece_cols = array[TNUM]			//Colours (copied from Commons image)
{< 226, 246, 0>,//, TRANSP>, 
< 29, 26, 216>,//, TRANSP>, 
< 255, 93, 223>,//, TRANSP>, 
< 3, 0, 255>,//, TRANSP>,
< 0, 225, 0>,//, TRANSP>,
< 0, 255, 236>,//, TRANSP>,
< 255, 0, 204>,//, TRANSP>,
< 0, 180, 165>,//, TRANSP>,
< 144, 238, 144>,//, TRANSP>,
< 255, 0, 3>,//, TRANSP>,
< 52, 6, 179>,//, TRANSP>,
< 179, 178, 6>,//, TRANSP>
}

#declare order = array[TNUM]			//Which pieces show first?
{4, 0, 7, 3, 11, 8, 5, 10, 6, 9, 1, 2}

#declare extindex = 0;
#while (extindex < clock)		//We pass all the pieces...




	#if (extindex < TNUM)			//... but we show only the first ones
	#declare index = order[extindex];
	union
	{

	#declare cubex = 0;
	#while (cubex < OSITY)

		object{
		cubo translate cubestructs[index][cubex]
		}

	#declare cubex = cubex + 1;

	#end

	pigment {color rgbt piece_cols[index]/255}

	rotate pos_rot[index][0] translate pos_rot[index][1]


	}

	#end

	#declare extindex = extindex + 1;

#end