File:Impedance mismatch due to absorption.gif
Impedance_mismatch_due_to_absorption.gif (360 × 359 pixels, file size: 2.44 MB, MIME type: image/gif, looped, 73 frames, 7.3 s)
Captions
Summary
[edit]DescriptionImpedance mismatch due to absorption.gif |
English: A positive imaginary part of the refractive index means the wave will be absorbed.
But, contrary to intuition, if you keep increasing absorption, the material will behave like a mirror, not a perfect absorber. |
Date | |
Source | https://twitter.com/j_bertolotti/status/1465294009325260802 |
Author | Jacopo Bertolotti |
Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 12.0 code
[edit]\[Sigma] = 5.; \[Lambda]0 = 2.; k0 = N[(2 \[Pi])/\[Lambda]0]; \[Delta] = \[Lambda]0/10; \[CapitalDelta] = 40*\[Lambda]0;
\[Phi]in = Table[0, {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
dim = Dimensions[\[Phi]in][[1]]
d = \[Lambda]0/2; (*typical scale of the absorbing layer*)
Imn = Table[10 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) + E^((y - \[CapitalDelta]/2)/d)), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)
ReMapC[x_] := RGBColor[(2 x - 1) UnitStep[x - 0.5], 0, (1 - 2 x) UnitStep[0.5 - x]];
\[Alpha][t_] := 2*t^3;
frames = Table[
Ren = Table[ If[y < 0, 1, 1 + I*\[Alpha][t] ], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
n = Ren + I Imn;
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
sourcef[x_, y_] := E^(-((x + (\[CapitalDelta]/4) )^2/(2 \[Sigma]^2))) E^(I 1.5 x) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y);
\[Phi]in = Table[Chop[sourcef[x, y] ], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
\[Phi]s = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
ArrayPlot[
Transpose[((Re[\[Phi]s])[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]/0.012)^1], ColorFunction -> ReMapC , DataReversed -> True, Frame -> False, PlotRange -> {-1, 1}, ClippingStyle -> {Blue, Red}, Epilog -> {White, Line[{{0, 180}, {400, 180}}], Text[Style["n=1", Bold, 20], {30, 160}], Text[Style[ StringForm["n=1+i``", NumberForm[\[Alpha][t], {3, 2}]], Bold, 20], {60, 200}]}]
, {t, 0.000, 1, 0.03}];
ListAnimate[Join[frames, Table[frames[[-1]], 5], Reverse[frames]]]
Licensing
[edit]This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. | |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 14:48, 30 November 2021 | 360 × 359 (2.44 MB) | Berto (talk | contribs) | Uploaded own work with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
File usage on other wikis
The following other wikis use this file:
- Usage on ca.wikipedia.org
- Usage on en.wikipedia.org
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
GIF file comment | Created with the Wolfram Language : www.wolfram.com |
---|