File:Euro exchange rate to GBP 2000 to 2018.svg

# gnuplot script for plotting eurofxref-hist.csv as obtained from
#  http://www.ecb.int/stats/exchange/eurofxref/html/index.en.html

# download and unzip data if not available - delete eurofxref* to force new download.
# remove or comment out these lines in Windows/MacOS.
! [ -f eurofxref-hist.csv ] || wget http://www.ecb.int/stats/eurofxref/eurofxref-hist.zip
! [ -f eurofxref-hist.csv ] || unzip eurofxref-hist.zip

#input
set timefmt "%Y-%m-%d"
set datafile missing 'N/A'
set datafile separator ','

#output
set key top left
set style data lines
set grid

set xdata time
set format x '%Y'
set xrange ['2000-01-01':'2018-01-01']
set mxtics 4
#set xlabel 'Date'

set ylabel 'GBP'
set format y '%.2f'

## gnuplot for SVG - gnuplot 4.2 / Ubuntu 8.10 
set term svg size 800,400 font "Liberation Sans,Arial,20"

set outp 'Euro_exchange_rate_to_GBP_2000_to_2018.svg'
set style line 1 lt rgb 'blue' lw 1

#available currencies:
#first one is $2, second $3 and so on
#USD,JPY,BGN,CYP,CZK,DKK,EEK,GBP,HUF,LTL,LVL,MTL,PLN,ROL,RON,SEK,SIT,SKK,CHF,ISK,NOK,HRK,RUB,TRL,TRY,AUD,BRL,CAD,CNY,HKD,IDR,ILS,INR,KRW,MXN,MYR,NZD,PHP,SGD,THB,ZAR

plot 'eurofxref-hist.csv' usi 1:($9) title '1 Euro in GBP' ls 1