File:Chebyshev type I order 3 bandstop filter 2023 228 2.gif

Summary[edit]

DescriptionChebyshev type I order 3 bandstop filter 2023 228 2.gif	English: Magnitudes of the S-parameters of a prototype Chebyshev type I bandstop filter of order 3 (ripple parameter 0.01), with the center series LC circuit inductor’s self-resonance frequency changing from 2 ω0 to 1000 ω0. (The other inductors are assumed to have no stray capacitance.) The horizontal arrow under the center of the plot shows the (somewhat arbitrary choosen for this example) intended stop band: from ω0 ∕ 1.25 to 1.25 ω0 at the −15 dB transmission level (ideally, the filter would maintain transmission below this value from about ω0 ∕ 1.276 to about 1.276 ω0.) There’re two additional lines corresponding to |S21| = 1 − 0.02 (i. e., twice the ripple level) and |Sij| = √½ (the case of exactly half the power being reflected, and thus exactly half the power passing through the network.) As we disregard losses in this model, |S11| = |S22| (which is often not the case for real, lossy circuits.) Русский: Модули S-параметров режекторного фильтра Чебышева первого рода порядка 3 (с параметром 0.01), в котором частота собственного резонанса индуктора центрального (последовательного) контура меняется от 2 ω0 до 1000 ω0. Горизонтальная стрелка ниже центра графика показывает (выбранную несколько произвольно для данного примера) целевую полосу подавления: от ω0 ∕ 1.25 до 1.25 ω0 по уровню пропускания −15 dB (идеальный фильтр обеспечивает подавление не хуже данного в полосе от примерно ω0 ∕ 1.276 до примерно 1.276 ω0.) Дополнительно проведены линии |S21| = 1 − 0.02 (т. е. удвоенное значение параметра фильтра) и |Sij| = √½ (случай равенства мощностей проходящей и отраженной волны: обе равны половине мощности падающей волны.) Поскольку мы пренебрегаем потерями в данной модели, |S11| = |S22| (что зачастую не выполняется для реальных цепей.)   This plot was created with Gnuplot.
Date	16 August 2023
Source	Own work
Author	Ivan Shmakov
Other versions

Gnuplot source code[edit]

### 228.002.gp  -*- Gnuplot -*-

### Code:

j = { 0, 1 }
dB (S) = (20 / log (10)) * log (abs (S))
array R_c[2]

array v[18]
array Y[4]
array Z[4]

## The following expressions are obtained through Maxima
S_YZ_generic (s) = ( \
    v[1] = Z[3] * Y[4], \
    v[2] = Y[3] * (v[1] + 1.), \
    v[3] = Z[2] * (v[2] + Y[4]), \
    v[4] = Y[2] * (v[3] + v[1] + 1.), \
    v[5] = Z[1] * (v[4] + v[2] + Y[4]) + v[3] + v[1] + 1., \
    v[6] = R_c[2] * v[5], \
    v[7] = Y[1] * v[5] + v[4] + v[2] + Y[4], \
    v[8] = - R_c[1] * R_c[2] * v[7], \
    v[9] = Y[4] * Z[4], \
    v[10] = Z[3] * (v[9] + 1.), \
    v[11] = Y[3] * (v[10] + Z[4]), \
    v[12] = Z[2] * (v[11] + v[9] + 1.), \
    v[13] = Y[2] * (v[12] + v[10] + Z[4]), \
    v[14] = Z[1] * (v[13] + v[11] + v[9] + 1.), \
    v[15] = v[14] + v[12] + v[10] + Z[4], \
    v[16] = Y[1] * v[15] + v[13] + v[11] + v[9] + 1., \
    v[17] = R_c[1] * v[16] , \
    v[18] = 1. / (R_c[1] * R_c[2] * v[7] + v[6] + v[17] \
                  + v[14] + v[12] + v[10] + Z[4]), \
    0)
S11_YZ (s) = ( \
    S_YZ (s), \
    v[18] * (v[8] + v[6] - R_c[1] * v[16] \
             + v[14] + v[12] + v[10] + Z[4]))
S12_YZ (s) = ( \
    S_YZ (s), \
    2 * R_c[1] * (v[5] * v[16] - v[7] * v[15]) * v[18])
S21_YZ (s) = ( \
    S_YZ (s), \
    2 * R_c[2] * v[18])
S22_YZ (s) = ( \
    S_YZ (s), \
    v[18] * (v[8] - R_c[2] * v[5] + v[17] + v[14] + v[12] + v[10] + Z[4]))

## 3-order bandstop
S_YZ_1 (s) = ( \
    Z[1] = 1. / (1. / (s * L1) + s * C1), \
    Y[2] = 1. / (1. / (s * C2) + 1. / (1. / (s * L2) + s * Cx2)), \
    Z[2] = 1. / (1. / (s * L3) + s * C3), \
    Y[1] = Y[3] = Z[3] = Y[4] = Z[4] = 0, \
    S_YZ_generic (s))

## Chebyshev prototype, parameter 0.01
R_c[1] = R_c[2] = 1.
C1 = C3 = 1. / (L1 = L1_0 = L3 = 1.18322866550682)
L2      = 1. / (C2 = 1.154356728371284)

w_0 = 1. ; w_l = w_0 / 3.2 ; w_r = w_0 * 23.
l_1 = -15 ; w_1 = 1.25
set arrow 100 heads
set arrow 100 from 1. / w_1, l_1 to w_1, l_1
set arrow 105 nohead

S_YZ (s) = S_YZ_1 (s)

##  NB: the following non-ASCII characters are used below
##      U+00bd VULGAR FRACTION ONE HALF
##      U+03c9 GREEK SMALL LETTER OMEGA
##      U+221a SQUARE ROOT
##      U+22c5 DOT OPERATOR

set logscale x
set key bottom left
set grid
set xtics  ("{/Italic ω}_0 / 2" 1. / 2, \
            "{/Italic ω}_0" 1., \
            "2 {/Italic ω}_0" 2., \
            "5 {/Italic ω}_0" 5., \
            "10 {/Italic ω}_0" 10., \
            "20 {/Italic ω}_0" 20.)
set xlabel "{/Italic ω}"
set ylabel "|{/Italic S_{ij}}|, dB"

set terminal png enhanced notruecolor font "DejaVuSansMono"
set samples 311, 311
ra = 43
w_s0 = 2.
pm = (log (1e3) - log (w_s0)) / ra
do for [ p = 0 : ra ] {
    set output sprintf ("228.002.%02d.png", p)
    w_s = w_s0 * exp (pm * p)
    Cx2 = 1. / (L2 * w_s)
    set arrow 105 from w_s, -21 to w_s, 1
    set arrow 100 lc   (dB (S21_YZ (j * w_1)) < -15 \
                        && dB (S21_YZ (j / w_1)) < -15 ? 2 : 7)
    set label 100 \
        sprintf  ("{/Italic ω}_{sr} = %7.1f {/Italic ω}_0", w_s) \
        at screen .2, .3
    plot [ w = w_l : w_r ] [ -21 : 1 ] \
        dB (S21_YZ (j * w)) title "|{/Italic S}_{21}| = |{/Italic S}_{12}|", \
        dB (S11_YZ (j * w)) title "|{/Italic S}_{11}| = |{/Italic S}_{22}|", \
        dB (1 - 0.02) title "1 - 2 ⋅ 0.01", .5 * dB (.5) title "√½"
    # pause (.1)
}

### 228.002.gp ends here

Licensing[edit]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse