File:COVID-19-Pandemie - KW (Kuwait) - Tote (800px).svg
Jump to navigation
Jump to search
Size of this PNG preview of this SVG file: 800 × 450 pixels. Other resolutions: 320 × 180 pixels | 640 × 360 pixels | 1,024 × 576 pixels | 1,280 × 720 pixels | 2,560 × 1,440 pixels.
Original file (SVG file, nominally 800 × 450 pixels, file size: 477 KB)
Captions
Captions
Add a one-line explanation of what this file represents
Summary[edit]
| Description |
Deutsch: COVID-19-Pandemie - KW (Kuwait) - Tote (800px) |
||
| Date | laufende Aktualisierungen | ||
| Source | Daten von der WHO - https://covid19.who.int/WHO-COVID-19-global-data.csv - durch Klicken auffindbar über https://covid19.who.int/table | ||
| Author | Summer ... hier! | ||
| SVG development |  This COVID-19 chart was created with Gnuplot.  This plot uses embedded text that can be easily translated using a text editor. | ||
| Source code |
# input (Zeitformat und Separator definieren)
#
set timefmt "%Y-%m-%d"
set datafile separator ';'
# Variablen zeile_X_stat setzten
# (every ::0 steht für 'ab erster Zeile' und kann weggelassen werden)
stats $WHO_data every ::0 using 5 name "zeile_5_stat" nooutput
stats $WHO_data every ::0 using 6 name "zeile_6_stat" nooutput
stats $WHO_data every ::0 using 7 name "zeile_7_stat" nooutput
stats $WHO_data every ::0 using 8 name "zeile_8_stat" nooutput
# Start und Ende ermitteln und Label setzen (incl. Konsolenausgabe)
stats $WHO_data every ::0 u (strptime("%Y-%m-%d",strcol(1))) name "datum" nooutput
print ' -----Stats-(Timestamp)----'
print ' Start: ', strftime("%d. %B %Y",datum_min)
print ' Ende: ', strftime("%d. %B %Y",datum_max)
print ' --------------------------'
# label fuer Grafikueberschrtft oben links mit den ermittelten Werten setzen
set label 'Daten vom '.strftime("%d.%m.%y",datum_min).' bis '.strftime("%d.%m.%y",datum_max) at graph 0.03, graph 0.93
# als Workaround nehmen wir statt zweimal 'ylabel' hier zweimal 'label'
# (bei multiplot ist es schwierig fuer alle Plots ein ylabel mit gleichen seitl. Einzug zu finden)
set label "Tote (kumuliert)" at screen 0.017, 0.700 rotate by +90 center
set label "Tote" at screen 0.017, 0.300 rotate by +90 center
# output
#
# Name der SVG-Datei
set output 'COVID-19-Pandemie_-_KW_(Kuwait)_-_Tote_(800px).svg'
unset key # keine Box fuer Legende
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set xtics scale 0.7, 0.4 # Skalenstriche x-Achse etwas kleiner
set ytics scale 0.7, 0.4 # Skalenstriche y-Achse etwas kleiner
set ytics offset 0.4, 0.0 # Zahlen eine Idee nach rechts (mehr Abstand vom Label)
# 'Wasserzeichen' für commonsprüfung
set label 'KW' at screen 0.01, 0.02 textcolor rgb '#ffffff' font 'Arial,8'
# Gitterlinienen per Hand setzen
set style line 1 linetype rgb '#4f4f4f' linewidth 0.25 # Def. Major-grid
set style line 2 linetype rgb '#9f9f9f' linewidth 0.20 # def. Minor-grid
unset grid
set grid noxtics nomxtics # Keine Gitterlinen an der 1. X-Achse (Monate)
set grid x2tics nomx2tics # Gitterliniene an der 2. X-Achse (Kalenderwochen)
set grid ytics mytics # Gitterl. an der Y-Achse
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle fuer Major u. Minor
# X-Achsenbeschriftung:
# ueber x1 machen wir die Monatsbschriftung, ueber x2 die Kalenderwochenbeschriftung
#
# beide X-Achsen, also x1 und x2, als Zeitachse definieren
set xdata time
set x2data time
# Bereich (von - bis) der X-Achse definieren
# Beginnt am 1. Jan. 2020 und Edit heute plus 6 Tage
xrange_max=strftime("%Y-%m-%d", time(0) + (60*60*24*6))
# zuvor Berechnetes xrange_max setzten
set xrange ['2020-01-01': xrange_max]
set x2range ['2020-01-01': xrange_max]
# die Maker fuer Monat setzen wir per Hand. Als 'format' geben wir einen leeren String an damit
# kein Text generiert wird (fuer die untere Grafik setzen wir den Text spaeter)
set xtics format "" # Format auf Nichts damit gnuplot die folgenden Daten nicht aufloest
set xtics ( "2020-01-01" \
, "2020-02-01" \
, "2020-03-01" \
, "2020-04-01" \
, "2020-05-01" \
, "2020-06-01" \
, "2020-07-01" \
, "2020-08-01" \
, "2020-09-01" \
, "2020-10-01" \
, "2020-11-01" \
, "2020-12-01" \
, "2021-01-01" \
, "2021-02-01" \
, "2021-03-01" \
)
#
# Kalenderwochen-Striche
#
# fuer x2 (KW) ebendalls keine Beschriftung
set format x2 ''
# der 6. Jan. 2020 war ein Montag - da setzen wir den ersten Strich und die
# folgenden Striche alle 7 Tage (hier in 60 * 60 * 24 * 7 Sekunden)
set x2tics '2020-01-06', 60 * 60 * 24 * 7
set x2tics scale 0
set xtics nomirror
unset mxtics
# Format Y-Achse
set decimalsign locale "de_DE.utf8"
set format y "%'.0f"
set yrange [-50:*]
set ytics 200
set mytics 5
set ytics nomirror
# Zebramuster
set style rect fillcolor lt -1 fillstyle solid 0.06 noborder
do for [i=1:12:2] {
marker_start=sprintf("2020-%1.2d-01",i)
marker_stop =sprintf("2020-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
marker_start=sprintf("2021-%1.2d-01",i)
marker_stop =sprintf("2021-%1.2d-01",i+1)
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
}
# Groesse und Schrift definieren
#
# Zur Variablen 'datum_max' siehe oben
my_svg_name=strftime("COVID_%d_%m_%Y_KW",datum_max)
set term svg size 800,450 font "Arial,16" name my_svg_name
###########################################################################################
set lmargin 10.0 # linker Rand fuer Beschriftung Y-Achse sollte nicht auf Auto stehen
set rmargin 1.0 # rechter Rand
set tmargin 1.0 # top margin
set bmargin 0.0 # bottom margin
set multiplot
# Ausgabe oberer Graph
set size 1.000, 0.550 # Groesse der Grafik
set origin 0.000, 0.450 # def. der linken unteren Ecke
unset xlabel
plot $WHO_data usi 1:8 axis x1y1 tit 'Infizierte' lt rgb '#700070' lw 1.75 with lines
# Ausgabe unterer Graph
set tmargin 0.4 # Wert von oben ueberschreiben damit Grafiken enger zusammen
unset bmargin # oben wurde bottommargin auf null gesetzt - jetzt wieder auto damit Platz fuer Skala
unset label #
set size 1.000, 0.450
set origin 0.000, 0.000
# Wenn das Datumsintervall so gross wird das die Labels zu eng gesetzt sind
# hier jeden zweiten Eintrag loeschen!
set xtics rotate by +30 center offset -1.5,-0.6
set xtics add ( " 2020" "2020-01-01" \
, "1. Feb." "2020-02-01" \
, "1. März" "2020-03-01" \
, "1. Apr." "2020-04-01" \
, "1. Mai" "2020-05-01" \
, "1. Jun." "2020-06-01" \
, "1. Jul." "2020-07-01" \
, "1. Aug." "2020-08-01" \
, "1. Sep." "2020-09-01" \
, "1. Okt." "2020-10-01" \
, "1. Nov." "2020-11-01" \
, "1. Dez." "2020-12-01" \
, " 2021" "2021-01-01" \
, "1. Feb." "2021-02-01" \
, "1. März" "2021-03-01" \
)
set xlabel "Datum (Monats- und KW-Skala)"
set yrange [-2:*]
set ytics 10
set mytics 5
# Ueber den Wert von lw kann man die Sichtbarkeit bei kl. Aufl. regulieren
plot $WHO_data usi 1:7 axis x1y1 tit '' lt rgb '#700070' lw 0.75 with impulses
unset multiplot
|
_-_Tote_(800px).svg&action=edit§ion=1){kind=link}
Licensing[edit]
_-_Tote_(800px).svg&action=edit§ion=3){kind=link}
I, the copyright holder of this work, hereby publish it under the following license:
 
|
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
File history
Click on a date/time to view the file as it appeared at that time.
_-_Tote_(800px).svg&dir=prev){kind=link}
_-_Tote_(800px).svg&offset=20230713122313){kind=link}
_-_Tote_(800px).svg&offset=&limit=20){kind=link}
_-_Tote_(800px).svg&offset=&limit=50){kind=link}
_-_Tote_(800px).svg&offset=&limit=100){kind=link}
_-_Tote_(800px).svg&offset=&limit=250){kind=link}
_-_Tote_(800px).svg&offset=&limit=500){kind=link}
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 13:49, 26 December 2023 | | 800 × 450 (477 KB) | Summer ... hier! (talk | contribs) | update |
| 16:40, 30 October 2023 |  | 800 × 450 (461 KB) | Summer ... hier! (talk | contribs) | update | |
| 07:27, 6 October 2023 |  | 800 × 450 (455 KB) | Summer ... hier! (talk | contribs) | update | |
| 18:47, 6 September 2023 |  | 800 × 450 (447 KB) | Summer ... hier! (talk | contribs) | update | |
| 15:47, 24 August 2023 |  | 800 × 450 (442 KB) | Summer ... hier! (talk | contribs) | update | |
| 09:48, 10 August 2023 |  | 800 × 450 (438 KB) | Summer ... hier! (talk | contribs) | update | |
| 00:45, 3 August 2023 |  | 800 × 450 (437 KB) | Summer ... hier! (talk | contribs) | update | |
| 11:46, 27 July 2023 |  | 800 × 450 (435 KB) | Summer ... hier! (talk | contribs) | update | |
| 21:35, 26 July 2023 |  | 800 × 450 (435 KB) | Summer ... hier! (talk | contribs) | update | |
| 12:23, 13 July 2023 |  | 800 × 450 (431 KB) | Summer ... hier! (talk | contribs) | update |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
File usage on other wikis
The following other wikis use this file:
- Usage on de.wikipedia.org
- Usage on fr.wikipedia.org
_-_Tote_(800px).svg&oldid=844520712){kind=link}