File:Standard symmetric pdfs logscale.svg

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Original file (SVG file, nominally 400 × 300 pixels, file size: 235 KB)

Captions

Captions

Add a one-line explanation of what this file represents

Summary

[edit]
Description
English: Logscale plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak:
 
red, kurtosis 3, Laplace (D)ouble exponential distribution;
 
orange, kurtosis 2, hyperbolic (S)ecant distribution;
 
green, kurtosis 1.2, (L)ogistic distribution;
 
black, kurtosis 0, (N)ormal distribution;
 
cyan, kurtosis −0.593762…, raised (C)osine distribution;
 
blue, kurtosis −1, (W)igner semicircle distribution;
 
magenta, kurtosis −1.2, (U)niform distribution.
Date
Source MarkSweep
Author  
Vector:
Permission
(Reusing this file)
Public domain This chart is ineligible for copyright and therefore in the public domain, because it consists entirely of information that is common property and contains no original authorship. For more information, see Commons:Threshold of originality § Charts

العربية | Deutsch | English | español | français | italiano | 日本語 | македонски | română | русский | slovenščina | 中文（简体） | 中文（繁體） | +/−

I, the copyright holder of this work, hereby publish it under the following license:
Creative Commons CC-Zero This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.

Other versions File:Standard symmetric pdfs.svg
File:Standard symmetric pdfs.png
File:Standard symmetric pdfs logscale.png
SVG development
InfoField
 
The SVG code is valid.
 
This chart was created with Gnuplot.
Source code
InfoField
Gnuplot code
# Laplace double exponential distribution, kurtosis 3
laplace(x) = exp(-abs(x)*sqrt(2)) * sqrt(0.5)

# sech distribution, kurtosis 2
sech(x) = 2.0 / (exp(x) + exp(-x))
sech_pdf(x) = 0.5 * sech(0.5*pi*x)

# logistic distribution, kurtosis 1.2
slogist = sqrt(3) / pi
logist(x) = exp(-x/slogist) / slogist / (1 + exp(-x/slogist))**2

# normal distribution, kurtosis 0
n(x) = exp(-0.5*x*x) / sqrt(2*pi)

# raised cosine distribution, kurtosis -0.59376
scos = 1.0 / sqrt(1/3.0 - 2/pi**2)
cosine(x) = abs(x)>scos? 0 : (1+cos(x*pi/scos))*0.5/scos

# Wigner semicircle distribution, kurtosis -1
wigner(x) = abs(x)>2? 0 : sqrt(4-x*x)*0.5/pi

# uniform distribution, kurtosis -1.2
uniform(x) = abs(x)>sqrt(3)? 0 : 0.5/sqrt(3)

set samples 6001
set grid

set xrange [-10.4:10.4]

set logscale y
set yrange [1e-24:5]
set ytics 1e3

set key right bottom font ",8" enhanced

set terminal svg size 400,300 enhanced fname 'DejaVu Sans'  fsize 10 butt solid
set output 'Standard symmetric pdfs logscale.svg'

plot \
     laplace(x)  lt 1 lw 2 title "D,  3", \
     sech_pdf(x) lt 8 lw 2 title "S,  2", \
     logist(x)   lt 2 lw 2 title "L,  1.2", \
     n(x)        lt 7 lw 2 title "N,  0", \
     cosine(x)   lt 5 lw 2 title "C, -0.59376", \
     wigner(x)   lt 3 lw 2 title "W, -1", \
     uniform(x)  lt 4 lw 2 title "U, -1.2"

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current16:07, 26 May 2020Thumbnail for version as of 16:07, 26 May 2020400 × 300 (235 KB)Andel (talk | contribs)== {{int:filedesc}} == {{Information |description=|Description= {{en|1=Logscale plot of several symmetric unimodal probability densities with unit variance. From highest to lowest peak: {{Legend|red|red, kurtosis 3, Laplace (D)ouble exponential distribution;}} {{Legend|orange|orange, kurtosis 2, hyperbolic (S)ecant distribution;}} {{Legend|green|green, kurtosis 1.2, (L)ogistic distribution;}} {{Legend|...

You cannot overwrite this file.

The following page uses this file:

File usage on other wikis

The following other wikis use this file:

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Standard_symmetric_pdfs_logscale.svg&oldid=832084372"