File:Qm tunneling timedomain.gif

f[e_, V_, a_, b_, x_] := 
 E^((Sqrt[2] Sqrt[-e m + m V] x)/\[HBar]) a + 
  E^(-((Sqrt[2] Sqrt[-e m + m V]
      x)/\[HBar])) b; (*Solution of the time-independent Schrodinger \
equation for a constant potential V*)

df[e_, V_, a_, b_, x_] := 
 Evaluate@FullSimplify[D[f[e, V, a, b, x], x] ];
coeff = FullSimplify[Solve[{f[e, V0, 1, b, l1] == f[e, V1, c, d, l1],
    df[e, V0, 1, b, l1] == df[e, V1, c, d, l1],
    f[e, V0, a2, 0, l2] == f[e, V1, c, d, l2], 
    df[e, V0, a2, 0, l2] == df[e, V1, c, d, l2]}, {b, c, d, 
    a2}] ]; (*impose continuity and smoothness to find all the needed \
coefficients*)
xmin = -100;
xmax = 100;
\[HBar] = 1.;
m = 1.;
V0 = 0;
V1 = 1;
l1 = 5;
l2 = 7;
e =.;
g = Piecewise[{{f[e, V0, 1, b, x] /. coeff, 
     x <= l1}, {f[e, V1, c, d, x] /. coeff, 
     l1 < x < l2}, {f[e, V0, a2, 0, x] /. coeff, 
     x >= l2}}]; (*Complete solution as a function of the energy e*)
\[Sigma] = 0.05;
e0 = 0.5; fevo = 
 Table[Flatten[
   Table[(E^(-((e - e0)^2/(2 \[Sigma]^2))) g) /. {e -> j}, {x, xmin, 
     xmax, 0.201}]], {j, 0., 1., 0.0011}];
evo = Transpose[InverseFourier /@ (Transpose[fevo]) ];
p1 = Table[If[j != 0,
   Show[
    Plot[50*HeavisidePi[(x - 6)/2], {x, xmin, xmax}, 
     PlotStyle -> {Red}, Filling -> Bottom],
    ListPlot[Abs[evo[[j]] ]^2, PlotRange -> All, 
     DataRange -> {xmin, xmax}, Joined -> True, 
     PlotStyle -> {Black}],
    PlotRange -> {0, 50}, Axes -> False,
    Epilog -> Inset[
      Show[
       Plot[50*HeavisidePi[(x - 6)/2], {x, xmin, xmax}, 
        PlotStyle -> {Red}, Filling -> Bottom],
       ListPlot[Abs[evo[[j]] ]^2, DataRange -> {xmin, xmax}, 
        Joined -> True, PlotStyle -> {Black}, PlotRange -> All]
       , PlotRange -> {{l1 - 2, l2 + 2}, {0, 15}}, Axes -> False, 
       Frame -> True, FrameTicks -> None
       ], {60, 35}, Automatic, 60]
    ]
   ], {j, -25, 25}]
ListAnimate[Drop[p1, {26}]]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse

This file, which was originally posted to https://twitter.com/j_bertolotti/status/1030470604418428929, was reviewed on 29 December 2018 by reviewer Ronhjones, who confirmed that it was available there under the stated license on that date.