File:Mutual Extintion.gif
Jump to navigation
Jump to search
No higher resolution available.
Mutual_Extintion.gif (300 × 376 pixels, file size: 5.56 MB, MIME type: image/gif, looped, 112 frames, 11 s)
Captions
Captions
Visualization of the concept of "mutual extintion" in optics.
Summary
[edit]
| Description |
English: If you send a collimated beam toward a small obstacle, some of the light will be scattered, but most will continue in the same direction. If now you send a second beam and vary its phase, you can modulate how much light goes "straight" in the first beam.
The reason this is possible is because some of the light from the second beam is scattered in the same direction on the first one, and will interfere with it. Inspired by: https://journals.aps.org/pra/abstract/10.1103/PhysRevA.104.043515 |
| Date | |
| Source | https://twitter.com/j_bertolotti/status/1458448502363729928 |
| Author | Jacopo Bertolotti |
| Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 12.0 code
[edit]
ReMapC[x_] := RGBColor[(2 x - 1) UnitStep[x - 0.5], 0, (1 - 2 x) UnitStep[0.5 - x]];
\[Sigma] = 4.; \[Lambda]0 = 2.; k0 = N[(2 \[Pi])/\[Lambda]0]; \[Delta] = \[Lambda]0/20; \[CapitalDelta] = 40*\[Lambda]0;
\[Phi]in = Table[0, {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
dim = Dimensions[\[Phi]in][[1]];
d = \[Lambda]0/2; (*typical scale of the absorbing layer*)
Ren = Table[ If[Sqrt[x^2 + y^2] <= \[Lambda]0/8, 4, 1], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
Imn = Table[ 10 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) + E^((y - \[CapitalDelta]/2)/d)), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)
n = Ren + I Imn;
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
sourcef1[x_, y_, t_] := E^(-((x + (\[CapitalDelta]/4) )^2/(2 \[Sigma]^2))) E^(I 1.5 x) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y) + t*E^(-((x - (\[CapitalDelta]/4) )^2/(2 \[Sigma]^2))) E^(-I 1.5 x) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y);
frames1 = Table[
\[Phi]in = Table[Chop[sourcef1[x, y, t] ], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in];
\[Phi]s = Partition[LinearSolve[M, b], dim];
Grid[{{
ListPlot[(Transpose[ Abs[\[Phi]s][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]/0.015][[-1]])^2, Axes -> False, AspectRatio -> 0.2, Joined -> True, PlotStyle -> Green, Background -> Black, PlotRange -> {0, 0.07}, ImagePadding -> 5, ImageSize -> 300]
}, {
ImageAdd[
ArrayPlot[Transpose[((Re[\[Phi]in + \[Phi]s])[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]/0.015)^1], ColorFunction -> ReMapC , DataReversed -> True, Frame -> False, PlotRange -> {-1, 1}, ImagePadding -> None, ImageSize -> 300, ClippingStyle -> {Blue, Red}], ArrayPlot[Transpose@Re[(n - 1)/5] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel,
Frame -> False] ]
}}, Background -> Black]
, {t, 0, 1, 0.1}]
sourcef2[x_, y_, t_] := E^(-((x + (\[CapitalDelta]/4) )^2/(2 \[Sigma]^2))) E^(I 1.5 x) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y) + E^(-((x - (\[CapitalDelta]/4) )^2/(2 \[Sigma]^2))) E^(-I 1.5 x) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y) E^(I t);
frames2 = Table[
\[Phi]in = Table[Chop[sourcef2[x, y, t] ], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in];
\[Phi]s = Partition[LinearSolve[M, b], dim];
Grid[{{
ListPlot[(Transpose[ Abs[\[Phi]s][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]/0.015][[-1]])^2, Axes -> False, AspectRatio -> 0.2, Joined -> True, PlotStyle -> Green, Background -> Black, PlotRange -> {0, 0.07}, ImagePadding -> 5, ImageSize -> 300]
}, {
ImageAdd[
ArrayPlot[ Transpose[((Re[\[Phi]s])[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]/0.015)^1], ColorFunction -> ReMapC , DataReversed -> True, Frame -> False, PlotRange -> {-1, 1}, ImagePadding -> None, ImageSize -> 300, ClippingStyle -> {Blue, Red}],
ArrayPlot[Transpose@Re[(n - 1)/5] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel, Frame -> False] ]
}}, Background -> Black]
, {t, 0, 2 \[Pi] - 0.001, \[Pi]/20}]
ListAnimate[
Join[Table[frames1[[1]], 5], frames1, Table[frames1[[-1]], 5], frames2, frames2, Reverse[frames1]]]
Licensing
[edit]
I, the copyright holder of this work, hereby publish it under the following license:
 
|
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
|
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 09:38, 11 November 2021 | | 300 × 376 (5.56 MB) | Berto (talk | contribs) | Uploaded own work with UploadWizard |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
