File:Fractional OAM modes 3 to 4 svg.svg
Jump to navigation
Jump to search
Size of this PNG preview of this SVG file: 800 × 320 pixels. Other resolutions: 320 × 128 pixels | 640 × 256 pixels | 1,024 × 410 pixels | 1,280 × 512 pixels | 2,560 × 1,024 pixels | 4,600 × 1,840 pixels.
Original file (SVG file, nominally 4,600 × 1,840 pixels, file size: 4.06 MB)
Captions
Captions
Amplitude and phase profiles of fractional OAM modes with topological charges between 3 and 4
Summary
[edit]
| Description |
English: Numerical simulation of several fractional OAM modes, where helical phase profiles corresponding to the topological charges l = 3, 3.25, 3.5, 3.75, and 4 are imparted to a Gaussian beam and the beam is subsequently propagated using Fourier optics calculation. For l = 3, a single vortex of charge 3 is visible in the center and the beam corresponds to an integer OAM mode. For l = 3.25, the vortex splits into three vortices of charge 1. For l = 3.5, a series of additional vortices is visible along the positive x-axis in the phase profile, which is manifested as a half-line of intensity minimum in the amplitude profile. For l = 3.75, four vortices of charge 1 are visible, and finally for l = 4 these vortices merge into a single vortex with its topological charge equal to 4. Čeština: Numerická simulace několika zlomkových OAM módů, kde je Gaussovskému svazku po řadě dodán šroubovicovitý fázový profil odpovídající topologickým nábojům l = 3, 3,25, 3,5, 3,75 a 4 a svazek je posléze šířen prostorem s použitím výpočtu z Fourierovské optiky. Pro l = 3 je vidět uprostřed jediný optický vír s nábojem 3 a optický svazek odpovídá celočíselnému OAM módu. Pro l = 3,25 se tento vír štěpí na víry tři, každý s nábojem 1. Pro l = 3,5 je podél kladné x-ové poloosy ve fázovém profilu viditelná série dodatečných vírů, což se projevuje jako polopřímka minimální intenzity v profilu amplitudy. Pro l = 3,75 lze vidět čtyři víry s nábojem 1 a konečně pro l = 4 se tyto víry slévají do víru jediného o náboji 4. |
| Date | |
| Source | Own work |
| Author | JozumBjada |
Licensing
[edit]
I, the copyright holder of this work, hereby publish it under the following license:
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
Source code
[edit]
The figure was created using Wolfram language 12.0.0 for Microsoft Windows (64-bit) (April 6, 2019). The source code follows.
(* ::Package:: *)
(* ::Section:: *)
(*Routines*)
(* ::Input::Initialization:: *)
colorbarFun[colorfun_,{low_,mid_,high_},{minx_:0,maxx_:35},{miny_:-350,maxy_:350},fontFamily_:"Times New Roman"]:=Module[{textoff=20,lineoff=50,fontSize=60,plot},
plot=DensityPlot[y+miny,{x,minx,maxx},{y,miny,maxy},ColorFunction->colorfun,Frame->False,PlotRangePadding->None];
plot=First@Cases[InputForm@plot,_GraphicsComplex,Infinity,1];
Graphics[{
Rectangle[{-2+minx,miny},{maxx+1,maxy}],
plot,
Line[{
{{-2+minx,miny},{lineoff+maxx,miny}},
{{-2+minx,maxy+1},{lineoff+maxx,maxy+1}},
{{-2+minx,0},{maxx+textoff/2,0}}
}],
Text[Style[low,FontFamily->fontFamily,FontSize->fontSize],{textoff+maxx,miny},{-1,-1}],
Text[Style[mid,FontFamily->fontFamily,FontSize->fontSize],{textoff+maxx,0},{-1,0}],
Text[Style[high,FontFamily->fontFamily,FontSize->fontSize],{textoff+maxx,maxy},{-1,1}]
},ImageSize->{Automatic,(maxy-miny)},PlotRangePadding->None]
]
(* ::Input::Initialization:: *)
fourierShift[arr_]:=Module[{nx,ny},
{nx,ny}=Dimensions[arr];
RotateRight[#,Floor[nx/2]]&/@RotateRight[arr,Floor[ny/2]]
]
(* ::Input::Initialization:: *)
plotMagnitudePhase[charge_,zoomnum_:50,sanmplingnum_:2^10]:=Module[{num=sanmplingnum,farr,nx,ny,zoom,magn,phas,transfun,ftmode,inmode,w0=.1,dist=900,len=2,dx,\[Lambda]=808*^-9,imgSize=700},
dx=len/num;
inmode=Table[If[x==0&&y==0,1.,N@Exp[I charge ArcTan[x,y]]Exp[-(x^2+y^2)/w0^2]],{x,-(len/2)+dx,len/2,dx},{y,-(len/2)+dx,len/2,dx}];
inmode=inmode/Norm[inmode,"Frobenius"];
transfun=Table[N@Exp[I \[Pi] dist \[Lambda] (kx^2+ky^2)],{kx,-(1/(2dx)),1/(2dx)-1/len,1/len},{ky,-(1/(2dx)),1/(2dx)-1/len,1/len}];
transfun=fourierShift[transfun];
ftmode=Fourier[fourierShift[inmode]];
farr=fourierShift[InverseFourier[transfun ftmode]];
{nx,ny}=Dimensions[farr];
zoom=farr[[Floor[nx/2-zoomnum];;Floor[nx/2+zoomnum],Floor[ny/2-zoomnum];;Floor[ny/2+zoomnum]]];
zoom=Reverse@Transpose@Reverse[zoom];
magn=Normalize[Abs[zoom]^2,Max];
magn=ListDensityPlot[magn,ImageSize->imgSize,PlotRange->All,ColorFunction->ColorData["SunsetColors"],Frame->False,PlotRangePadding->None];
phas=Arg[zoom];
phas=ListDensityPlot[phas,ImageSize->imgSize,PlotRange->All,ColorFunction->Hue,Frame->False,PlotRangePadding->None];
{magn,phas}
]
(* ::Section:: *)
(*Computation*)
(* ::Input:: *)
(*charges34={3,3.25,3.5,3.75,4};*)
(*AbsoluteTiming[arrs34=plotMagnitudePhase/@charges34;]*)
(*{magn34,phas34}=Transpose[arrs34];*)
(* ::Input:: *)
(*colorBarMagn=colorbarFun["SunsetColors",{0,0.5,1},{0,35},{-350,350}];*)
(*colorBarPhas=colorbarFun[Hue,{Style[0,FontFamily->"Times"],\[Pi],Row[{Style[2,FontFamily->"Times"],"\[Pi]"}]},{0,35},{-350,350},Automatic];*)
(* ::Input:: *)
(*grid34=Grid[{Framed[Style["\[ScriptL] = "<>ToString[#],60,FontFamily->"Times"],Alignment->Center,ImageSize->{700,60},FrameStyle->Thick]&/@charges34,*)
(*Join[magn34,{colorBarMagn}],Join[phas34,{colorBarPhas}]}];*)
(* ::Section:: *)
(*Export*)
(* ::Input:: *)
(*SetDirectory[NotebookDirectory[]]*)
(* ::Input:: *)
(*Export["grid34.png",grid34,ImageResolution->200]*)
(* ::Input:: *)
(*Export["grid34.svg",grid34,ImageResolution->200]*)
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 19:11, 7 January 2022 | | 4,600 × 1,840 (4.06 MB) | JozumBjada (talk | contribs) | Cross-wiki upload from cs.wikipedia.org |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
File usage on other wikis
The following other wikis use this file:
- Usage on en.wikipedia.org
