File:Flag of Europe bw.svg

LibreLogo source:

; Created in LibreOffice 4.2 with this LibreLogo program
; Usage: Put this code into an English language document in LibO Writer,
; and click on the Start icon of the View»Toolbars»Logo toolbar.

; go to a vertex and store its coordinate 
TO vertex vertices n
FORWARD n
z = POSITION
vertices += [z]
BACK n
END

TO star n
golden_ratio = (1 + SQRT 5)/2
vertices = []
HEADING 0
REPEAT 5 [
    vertex vertices n
    RIGHT 360/10
    vertex vertices n - n / golden_ratio
    RIGHT 360/10
]
FOR i IN vertices [
    POSITION i
    PENDOWN
]
FILL
PENUP
END

TO flag name color1 color2 border
CLEARSCREEN HOME HIDETURTLE
PICTURE “Flag_of_Europe_%s.svg” % name [
x = PAGESIZE[0] – PAGESIZE[0]*2/3*2/25
y = x*2/3
PENCOLOR “INVISIBLE”
IF border=1 [
    FILLCOLOR “WHITE” 
    RECTANGLE [PAGESIZE[0], y + PAGESIZE[0]*2/3*2/25]
]
PENSIZE y/100 PENJOINT “MITER” PENDOWN
FILLCOLOR color1
IF color1 = 0xffffff [ PENCOLOR “BLACK” ]
RECTANGLE [x, y]
PENCOLOR “INVISIBLE”
FILLCOLOR color2
REPEAT 12 [
    PENUP 
    HEADING 360/12 * (REPCOUNT - 1)
    FORWARD y*1/3
    star y/18
    HOME
]
]
END

flag “bw” 0xffffff 0x000000 0
flag “bw_with_border” 0xffffff 0x000000 1
flag “color” 0x003399 0xffcc00 0
flag “color_with_border” 0x003399 0xffcc00 1
flag “blue” 0x003399 0xffffff 0
flag “blue_with_border” 0x003399 0xffffff 1

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse