File:Flüchtlingskrise ab 2015 in Deutschland.svg

Size of this PNG preview of this SVG file: 533 × 600 pixels. Other resolutions: 213 × 240 pixels | 427 × 480 pixels | 683 × 768 pixels | 910 × 1,024 pixels | 1,820 × 2,048 pixels.

Original file ‎(SVG file, nominally 800 × 900 pixels, file size: 162 KB)

Captions

English

Add a one-line explanation of what this file represents

Summary

Description	Deutsch: Flüchtlingskrise_ab_2015_in_Deutschland
Source	Own work
Author	Summer ... hier! (talk) 16:41, 23 June 2018 (UTC)

Licensing

I, the copyright holder of this work, hereby publish it under the following license:

	This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.
	The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. CC0falsefalse

Gnuplot script to generate this plot

This W3C-unspecified plot was created with Gnuplot.

W3C-validity not checked.

#!/usr/bin/gnuplot
# gnuplot 


#########################################################################
#                                                                       #
#                        Hier die Daten Ergänzen !                      #
#                                                                       #
#########################################################################
#
# Daten per Here-Document
# (zur tech. Beschreibung siehe Abschntt 'Inline data and datablocks' 
# in http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
#
$my_HereDoc << EndOfData
#
# 
# Quelle: die Daten stammen aus dem Artikel 'Flüchtlingskrise [ab 2015] 
# in Deutschland' (der Artikel wurde umbenannt). Im ersten Abschnitt 
# 'Zahlen und Fakten / Entwicklung' sind drei Grafiken mit der Vorlage 
# 'Graph' eingebunden. Die Daten sind dem Quelltext der Vorlage entnommen.
# (Stand Juni 2018)
# 
#
# Spalte 1: Datum
# Spalte 2: aus WP-Artikel übernommen (war Beschriftung X-Achse; hier nur Zierde)
# Spalte 3: Neuregistrierungen EASY/Kerndatensystem ab 2015 (monatsweise)
# Spalte 4: Erst- und Folgeanträge auf Asyl ab 2015 (monatsweise)
# Spalte 5: Anhängige Asylanträge beim BAMF ab Januar 2015
#
#
15.01.2015 ; 1     ; 32229      ; 25042       ; 178250
15.02.2015 ; 2     ; 38892      ; 26083       ; 188435
15.03.2015 ; 3     ; 31091      ; 32054       ; 199831
15.04.2015 ; 4     ; 33150      ; 27178       ; 209700
15.05.2015 ; 5     ; 37194      ; 25992       ; 220956
15.06.2015 ; 6     ; 53721      ; 35449       ; 237877
15.07.2015 ; 7     ; 82798      ; 37531       ; 254559
15.08.2015 ; 8     ; 104460     ; 36422       ; 276617
15.09.2015 ; 9     ; 163772     ; 43071       ; 300531
15.10.2015 ; 10    ; 181166     ; 54877       ; 328207
15.11.2015 ; 11    ; 206101     ; 57816       ; 355914
15.12.2015 ; 12    ; 127320     ; 48277       ; 364664
15.01.2016 ; '1    ; 91671      ; 52103       ; 371754
15.02.2016 ; '2    ; 61428      ; 67797       ; 393155
15.03.2016 ; '3    ; 20608      ; 59975       ; 409113
15.04.2016 ; '4    ; 15941      ; 60943       ; 431993
15.05.2016 ; '5    ; 16281      ; 55259       ; 459667
15.06.2016 ; '6    ; 16335      ; 74637       ; 495792
15.07.2016 ; '7    ; 16160      ; 74454       ; 526276
15.08.2016 ; '8    ; 18143      ; 91331       ; 567479
15.09.2016 ; '9    ; 15618      ; 76400       ; 579314
15.10.2016 ; '10   ; 15178      ; 32640       ; 547174
15.11.2016 ; '11   ; 17566      ; 26438       ; 490967
15.12.2016 ; '12   ; 16442      ; 20575       ; 433719
15.01.2017 ; ''1   ; 14476      ; 17964       ; 384523
15.02.2017 ; ''2   ; 14289      ; 16568       ; 333815
15.03.2017 ; ''3   ; 14976      ; 20136       ; 278006
15.04.2017 ; ''4   ; 11952      ; 14848       ; 232493
15.05.2017 ; ''5   ; 14973      ; 16641       ; 165099
15.06.2017 ; ''6   ; 12399      ; 15261       ; 146551
15.07.2017 ; ''7   ; 15069      ; 16844       ; 129467
15.08.2017 ; ''8   ; 16312      ; 18651       ; 114202
15.09.2017 ; ''9   ; 14688      ; 16520       ; 99334
15.10.2017 ; ''10  ; 15170      ; 17028       ; 87187
15.11.2017 ; ''11  ; 16135      ; 18711       ; 75660
15.12.2017 ; ''12  ; 12487      ; 14293       ; 68245
15.01.2018 ; '''1  ; 12907      ; 15077       ; 57693
15.02.2018 ; '''2  ; 10760      ; 12490       ; 55279
15.03.2018 ; '''3  ; 10712      ; 12622       ; 51968
15.04.2018 ; '''4  ; 11385      ; 13163       ; 51498
15.05.2018 ; '''5  ; 10849      ; 12494       ; 50373
#
#
#
EndOfData


# Variablen
#
my_data               = 'Flüchtlingskrise_ab_2015_in_Deutschland.dat'
my_xrange_min         = '01.01.2015' # Beginn des dargestellten Intervalls 
my_xrange_max         = '31.5.2018' # Ende des dargestellten Intervalls 
my_xtics_years        = '1'  # Skalenstrich pro Jahr
my_mxtics             = '12' # Monatsmarkierung


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key                  # keine Legende (direkt vorher gesetzt Werte unwirksam)
set style data lines       # wird bei 'plot' überschrieben 
set style fill transparent solid 0.4 # wird ebenfalls bei 'plot' überschrieben
set border 3               # Rahmen unten (Bit 1) und links (+ Bit 2) 
set grid                   # Gitterlinien verwenden
# Gitterlinienen per Hand setzen falls gewünscht 
set style line 1 linetype rgb '#696969' linewidth 0.5 dashtype 0 # Def. Major-grid
set style line 2 linetype rgb '#C9C9C9' linewidth 0.5 dashtype 3 # def. Minor-grid
set grid  xtics mxtics     # eventuell noxtics und nomxtics
set grid  ytics mytics     # eventuell noytics und nomytics
set grid  back             # Gitter im Hintergrund
set grid  linestyle 1, linestyle 2 # Setzen des linestyle für Major u. Minor 
#show grid                  # Kontrollausgabe auf der Konsole


# Bereiche/Format/etc X-Achse 
set xdata time             # X-Achse als Zeitachse
set xlabel 'Jahr'          # Beschriftung X-Achse
set xlabel offset 0, 0.75  # Schrift etwas höher
set xrange [ my_xrange_min : my_xrange_max]
                           # Wertebreich der X-Achse
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * my_xtics_years
                           # xtics in Sekunden 
                           # der Beginn (Wert vor dem Komma) der X-Einteilung 
                           # kann außerhalb xrange liegen
set xtics offset  0, 0.5   # Beschriftung näher an die X-Achse
set mxtics my_mxtics       # Skalenstriche 
set xtics nomirror         # Nur unten Skalieren
set format x '%Y'          # Beschriftungsformat JJJJ
set xtics  out             # Skal. aussen damit sie nicht von Grafik 
                           # überschr. wird


set ytics offset 0.5       # Schrift etwas nach rechts
set ytics nomirror         # oben keine Teilstriche
set decimalsign locale "de_DE.utf8" # Stelle Input und Output auf "," um 
                           # set decimalsign ',' würde nur Output umstellen, 
set format y  "%'.0f"      # Ausgabeformat
set ytics  out             # Skal. aussen da sie sonst von Grafik 
                           # überschr. wird
set mytics 5               # 
set ylabel offset 2.0, 0.0 # Beschriftung näher an die Y-Achse


# Hintergrund für Jahres-/Quatalsmarkierung
# Sich überlagernde transparente Rechtecke ...  
set style rect fillcolor lt -1 fillstyle solid 0.04 noborder
# ... mit for-Schleifen bis ins Jahr 2020 setzen 
set for [i=2015:2020:1] \
  object rectangle from '01.04.'.i, graph 0 to '31.12.'.i , graph 1 back 
set for [i=2015:2020:1] \
  object rectangle from '01.07.'.i, graph 0 to '31.12.'.i , graph 1 back 
set for [i=2015:2020:1] \
  object rectangle from '01.10.'.i, graph 0 to '31.12.'.i , graph 1 back 


# Alternative zur obigen Jahres-/Quatalsmarkierung
# (bisschen einfacher gestrckt als Variante oben)
# set style rect fillcolor lt -1 fillstyle solid 0.05 noborder
# # 2015
# set obj rect from '01.01.2015', graph 0 to '31.03.2015' , graph 1 back
# set obj rect from '01.07.2015', graph 0 to '30.09.2015' , graph 1 back
# # 2016
# set obj rect from '01.01.2016', graph 0 to '31.03.2016' , graph 1 back
# set obj rect from '01.07.2016', graph 0 to '30.09.2016' , graph 1 back
# # 2017
# set obj rect from '01.01.2017', graph 0 to '31.03.2017' , graph 1 back
# set obj rect from '01.07.2017', graph 0 to '30.09.2017' , graph 1 back
# # 2018
# set obj rect from '01.01.2018', graph 0 to '31.03.2018' , graph 1 back
# set obj rect from '01.07.2018', graph 0 to '30.09.2018' , graph 1 back


# Außenränder (keine Angabe entspricht Automatik)
set bmargin 
set lmargin 
set rmargin 1.5 # rechts entspr. der Wert bei Auto etwa 2.8
set tmargin 


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir bei UNIX in eine Pipe und sind so beim Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg) 
# Windowsbenutzer, die mit Pipes nicht umgehen könnten, sollten hier hier das 
# folgende 'set output ...' auskommentieren und den Dateinamen ggf. ersetzen. 
# set output 'Flüchtlingskrise_ab_2015_in_Deutschland.svg' 
set term svg size 800,900 font "Arial,18"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer 
# Einbindung [[Datei:Flüchtlingskrise_ab_2015_in_Deutschland.svg|mini|400px|Text]] noch Schrift/Details 
# erkennen kann. 


# Abkürzungen hinter dem Plot-Befehl:
#     u : using
#     w : with
#    lc : linecolor
#    lt : linetype 
#    lw : linewidth
#    pt : pointtype  
#    ps : pointsize
#    lp : linespoints
#     p : points
#     t : title
#   not : notitle


set multiplot
  set size              1.0, 0.35
  set origin            0.0, 0.65
  set xtics scale       1.0, 0.5
  set yrange            [0: 220000]
  set ytics             50000
  set ylabel            '   ' # KEIN 'unset' damit Positionen bleiben
  unset xlabel
  set format x          '%Y'
  set label             'Neuregistrierungen EASY/Kerndatensystem' \
                        at '15.04.2018', 205000 right
plot $my_HereDoc u 1:3 w lp lc rgb 'dark-blue' lt 1 lw 2.5 pt 7 ps 0.3 not
  set size              1.0, 0.35
  set origin            0.0, 0.32
  set xtics scale       1.0, 0.5
  set yrange            [0: 100000]
  set ytics             25000
  set ylabel            'Anzahl'
  unset xlabel
  set format x          '%Y'
  unset label           # Definiionen von oben löschen
  set label             'Erst- und Folgeanträge auf Asyl' \
                        at '15.04.2018', 93000 right
plot $my_HereDoc u 1:4 w lp lc rgb 'dark-blue' lt 1 lw 2.5 pt 7 ps 0.3 not
  set size              1.0, 0.35
  set origin            0.0, 0.0
  set xtics scale       1.0, 0.5
  set xtics format      '%Y'
  set xlabel offset     0.0, 1.0
  set xlabel            'Datum'
  set yrange            [0: 650000]
  set ytics             200000
  set ylabel            '   ' # KEIN 'unset' damit Positionen bleiben
  unset label           # Definiionen von oben löschen
  set label 'Anhängige Asylanträge beim BAMF' at '15.04.2018', 610000 right
plot $my_HereDoc u 1:5 w lp lc rgb 'dark-blue' lt 1 lw 2.5 pt 7 ps 0.3 not
unset multiplot 

quit

File history

Click on a date/time to view the file as it appeared at that time.

	Date/Time	Dimensions	User	Comment
current	16:41, 28 June 2018	800 × 900 (162 KB)	Summer ... hier! (talk \| contribs)	Zeitachse bei allen drei Teilgraphen beschriftet
	22:50, 23 June 2018	800 × 900 (162 KB)	Summer ... hier! (talk \| contribs)	Schrift etwas größer
	22:33, 23 June 2018	800 × 900 (162 KB)	Summer ... hier! (talk \| contribs)	Nach Kitik in https://de.wikipedia.org/w/index.php?title=Diskussion:Fl%C3%BCchtlingskrise_ab_2015_in_Deutschland&diff=178577696&oldid=178577605
	18:47, 23 June 2018	800 × 900 (132 KB)	Summer ... hier! (talk \| contribs)	Graustufen (wie telefonisch besprochen)
	16:41, 23 June 2018	800 × 900 (133 KB)	Summer ... hier! (talk \| contribs)	== {{int:filedesc}} == {{Information \|Description = {{de\|Einwohnerentwicklung von Flüchtlingskrise_ab_2015_in_Deutschland}} \|Source = {{own}} \|Author = ~~~~ \|Date = license = {{self\|Cc-zero}} }} == {{int:license-header}} == {{self\|Cc-zero}} == Gnuplot script to generate this plot == {{gnuplot}}{{ValidSVG}}<!--{{Created with Gnuplot \| v }}--> <source lang="gnuplot"> #!/usr/bin/gnuplot # gnuplot ########################################################...

You cannot overwrite this file.

File usage on Commons

There are no pages that use this file.

File usage on other wikis

The following other wikis use this file:

Usage on de.wikipedia.org
- Flüchtlingskrise in Deutschland 2015/2016
- Diskussion:Flüchtlingskrise in Deutschland 2015/2016/Archiv/3

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Short title	Gnuplot
Image title	Produced by GNUPLOT 5.0 patchlevel 3
Width	800
Height	900

File:Flüchtlingskrise ab 2015 in Deutschland.svg

Captions

Captions

Summary

Licensing

Gnuplot script to generate this plot

File history

File usage on Commons

File usage on other wikis

Metadata

Structured data

Items portrayed in this file

depicts

copyright status

copyrighted, dedicated to the public domain by copyright holder

copyright license

Creative Commons CC0 License

source of file

original creation by uploader

Navigation menu

File:Flüchtlingskrise ab 2015 in Deutschland.svg

Captions

Captions

Summary

Licensing

Gnuplot script to generate this plot

File history

File usage on Commons

File usage on other wikis

Metadata

Navigation menu

Search