File:Einwohnerentwicklung von Jülich.svg

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Original file(SVG file, nominally 800 × 400 pixels, file size: 78 KB)

Captions

Captions

Add a one-line explanation of what this file represents

Summary

[edit]
Description
Deutsch: Einwohnerentwicklung von Jülich
Source Own work
Author Summer ... hier! (talk) 11:19, 6 May 2018 (UTC)

Licensing

[edit]
I, the copyright holder of this work, hereby publish it under the following license:
Creative Commons CC-Zero This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.

Gnuplot script to generate this plot

[edit]
 
This W3C-unspecified plot was created with Gnuplot.
 
W3C-validity not checked.
#!/usr/bin/gnuplot
# gnuplot 


# Variablen - die wichtigsten Paramter dieser Grafik:
# (in der Regel wird es reichen für eine neue Grafik diese Werte zu ändern)
my_data               = 'Einwohnerentwicklung_von_Jülich.dat'
my_xrange_min         = '01.01.300'
my_xrange_max         = '31.12.2017'
my_xtics_years        = '200'
my_mxtics             = '5'
my_yrange_min         = '0'
my_yrange_max         = '35000'
my_ytics              = '10000'
my_ymtics             = '5'
ist_gemeinde          = '1' # 1 für ja, 0 für nein
                            # Falls ja, werden Marker für Grossstadt 
                            # und Mio.Stadt gesetzt
deut_teil             = '0' # 1 für ja, 0 für nein für Marker 'Deut. Teilung'


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"          # Zeitangaben in TT.MM.YYYY
set datafile separator ";"      # Spaltenseparator 
set datafile commentschars "#"  # Kommentarzeichen 
  stats my_data  u (strptime("%d.%m.%Y",strcol(1))) nooutput 
  my_diff = (STATS_max - STATS_min) / (60*60*24*365.25)
  print '     -----Stats-(Timestamp)----------------------'
  print '     Erster Wert der Datendatei:  ', strftime("%d.%m.%Y", STATS_min)
  print '     Letzter Wert der Datendatei: ', strftime("%d.%m.%Y", STATS_max)
  print '     Diff in Jahren:              ', my_diff
  print '     --------------------------------------------'
  # Anmerk.: die ausgegebenen Timestamps können in einer Shell bequem mit 
  # 'date -d @[Wert]' in humanleseriches Format gewandelt werden

# Allgemeines zur Ausgabe
set key vertical maxrows 6 # Max Anzahl Zeilen
set key left top           # Legende links oben
set key opaque             # ohne Transparenz 
set key samplen 2          # Breite der Linenbeispiele 
unset key                  # direkt vorher gesetzte Werte aufgehoben; ggf auskommentieren! 
set style data lines       # wird bei 'plot' überschrieben 
set style fill transparent solid 0.4 # wird ebenfalls bei 'plot' überschrieben
set border 3               # Rahmen unten (Bit 1) und links (+ Bit 2) 
set grid                   # Gitterlinien verwenden
# Gitterlinien per Hand setzen falls gewünscht 
set style line 1 linetype rgb '#696969' linewidth 0.5 dashtype 2 # Def. Major-grid
set style line 2 linetype rgb '#C9C9C9' linewidth 0.5 dashtype 3 # def. Minor-grid
set grid  xtics mxtics     # eventuell noxtics und nomxtics
set grid  ytics mytics     # eventuell noytics und nomytics
set grid  back             # Gitter im Hintergrund
set grid  linestyle 1, linestyle 2 # Setzen des linestyle für Major u. Minor 
#show grid                  # Kontrollausgabe auf der Konsole


# Farben - nummerische Equavalente zu Namen nach: 
# https://www2.uni-hamburg.de/Wiss/FB/15/Sustainability/schneider/gnuplot/colors.htm
# Die beiden Ziffen am Ende der Variablen geben  opacity/transparenz an
#
my_darkred_00       = '#008B0000';     my_darkred_20       = '#208B0000';
my_darkred_40       = '#408B0000';     my_darkred_60       = '#608B0000';
my_darkred_80       = '#808B0000';     my_darkred_a0       = '#a08B0000';
my_darkred_c0       = '#c08B0000';     my_darkred_e0       = '#e08B0000';
#
my_darkgreen_00     = '#00006400';     my_darkgreen_20     = '#20006400';
my_darkgreen_40     = '#40006400';     my_darkgreen_60     = '#60006400';
my_darkgreen_80     = '#80006400';     my_darkgreen_a0     = '#a0006400';
my_darkgreen_c0     = '#c0006400';     my_darkgreen_e0     = '#e0006400';
#
my_darkblue_00      = '#0000008B';     my_darkblue_20      = '#2000008B';
my_darkblue_40      = '#4000008B';     my_darkblue_60      = '#6000008B';
my_darkblue_80      = '#8000008B';     my_darkblue_a0      = '#a000008B';
my_darkblue_c0      = '#c000008B';     my_darkblue_e0      = '#e000008B';
#
my_darkmagenta_00   = '#008B008B';     my_darkmagenta_20   = '#208B008B';
my_darkmagenta_40   = '#408B008B';     my_darkmagenta_60   = '#608B008B';
my_darkmagenta_80   = '#808B008B';     my_darkmagenta_a0   = '#a08B008B';
my_darkmagenta_c0   = '#c08B008B';     my_darkmagenta_e0   = '#e08B008B';
# 
my_darkorange_00    = '#00FF8C00';     my_darkorange_20    = '#20FF8C00';
my_darkorange_40    = '#40FF8C00';     my_darkorange_60    = '#60FF8C00';
my_darkorange_80    = '#80FF8C00';     my_darkorange_a0    = '#a0FF8C00';
my_darkorange_c0    = '#c0FF8C00';     my_darkorange_e0    = '#e0FF8C00';
#
my_darkturquoise_00 = '#0000CED1';     my_darkturquoise_20 = '#2000CED1';
my_darkturquoise_40 = '#4000CED1';     my_darkturquoise_60 = '#6000CED1';
my_darkturquoise_80 = '#8000CED1';     my_darkturquoise_a0 = '#a000CED1';
my_darkturquoise_c0 = '#c000CED1';     my_darkturquoise_e0 = '#e000CED1'; 
#
my_black_00         = '#00000000';     my_black_20         = '#20000000';
my_black_40         = '#40000000';     my_black_60         = '#60000000';
my_black_80         = '#80000000';     my_black_a0         = '#a0000000';
my_black_c0         = '#c0000000';     my_black_e0         = '#e0000000';


# Bereiche/Format/etc X-Achse 
set xdata time             # X-Achse als Zeitachse
set xlabel 'Jahr'          # Beschriftung X-Achse
set xlabel offset 0, 0.75  # Schrift etwas höher
set xrange [ my_xrange_min : my_xrange_max]
                           # Wertebreich der X-Achse
set xtics '01.01.200', (60*60*24*365.25) * my_xtics_years
                           # xtics in Sekunden 
                           # der Beginn (Wert vor dem Komma) der X-Einteilung 
                           # kann außerhalb xrange liegen
set xtics offset  0, 0.5   # Beschriftung näher an die X-Achse
set mxtics my_mxtics       # Skalenstriche 
set xtics nomirror         # Nur unten Skalieren
set format x '%3Y'         # Beschr.format JJJJ (bei 3 Stellen o. führend 0)
set xtics  out             # Skal. aussen damit sie nicht von Grafik 
                           # überschr. wird


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label 
# Untere Begrenzung des Bereichs der Y-Achse
set yrange [ my_yrange_min : ]
# Obere  Begrenzung des Bereichs der Y-Achse
# wir Testen ob der Wert der Var.  my_yrange_max ein '*' ist und reagieren 
# entsprechend weil der '*' sich nicht direkt via Var. setzen lässt. 
if ( ( my_yrange_max eq '*' )) set yrange [ : *             ]
if (!( my_yrange_max eq '*' )) set yrange [ : my_yrange_max ]
set ytics my_ytics         # Anzahl der kleinen Teilstriche
set ytics offset 0.5       # Schrift etwas nach rechts
set ytics nomirror         # oben keine Teilstriche
set decimalsign locale "de_DE.utf8" # Stelle Input und Output auf "," um 
                           # set decimalsign ',' würde nur Output umstellen, 
set format y  "%'.0f"      # Ausgabeformat
set mytics my_ymtics       # Unterskalierung 
set ytics  out             # Skal. aussen da sie sonst von Grafik 
                           # überschr. wird


#### Markierungsbalken für die beiden Weltkriege etc.
# Die set-Befehle ggf. auskommentieren
# Attribute für Markierungsbalken
set style rect fillcolor lt -1 fillstyle solid 0.1 noborder
#
# == Dreißigjähriger Krieg
  set obj rect from '23.05.1618', graph 0 to '24.10.1648' , graph 1 back
  set label "Dreißigjähriger Krieg" at '30.06.1633', graph 0.8 rotate by +60 center front
# == Siebenjähriger Krieg
# set obj rect from '29.08.1756', graph 0 to '21.09.1762' , graph 1 back
# set label "Siebenjähriger Krieg"  at '30.06.1759', graph 0.8 rotate by +60 center front
# == Hamburger Franzosenzeit
# set obj rect from '30.06.1806', graph 0 to '30.06.1814' , graph 1 back
# set label "H. Franzosenzeit"      at '01.01.1810', graph 0.3 rotate by +60 center front
# == Befreiungskriege
# set obj rect from '26.02.1813', graph 0 to '20.11.1815' , graph 1 back
# set label "Befreiungskriege"      at '30.06.1814', graph 0.8 rotate by +60 center front
# == 1. Weltkrieg
  set obj rect from '28.07.1914', graph 0 to '11.11.1918' , graph 1 back
  set label "1. Weltkrieg"          at '30.06.1916', graph 0.9 rotate by +60 center front
# == 2. Weltkrieg
  set obj rect from '01.09.1939', graph 0 to '04.05.1945' , graph 1 back
  set label "2. Weltkrieg"          at '30.06.1942', graph 0.6 rotate by +90 center front
# == Dädärä
if (deut_teil eq '1') {
  set obj rect from '07.10.1949', graph 0 to '03.10.1990' , graph 1 back
  set label "Deut. Teilung"         at '01.01.1970', graph 0.9 rotate by +60 center front
}  
#
# == Markierung für Großstadtgrenze 
# prüfen,  ob bei  100.000 eine vertikale Linie gezogen werden soll 
if (ist_gemeinde eq '1') set arrow from my_xrange_min,  '100000' to my_xrange_max,  '100000' nohead lc rgb '#B0FF0000' back
# == Markierung für Millionenstadtgrenze 
# prüfen, ob bei 1.000.000 eine vertikale Linie gezogen werden soll 
if (ist_gemeinde eq '1') set arrow from my_xrange_min, '1000000' to my_xrange_max, '1000000' nohead lc rgb '#B0FF0000' back
# == Einzelwerte (Beispiel)
# set label 1 'Wert 1' at '25.05.1987',5000  point pointtype 3 pointsize 0.8
# set label 2 'Wert 2' at '09.05.2011',10000 point pointtype 3 pointsize 0.8


# Außenränder (keine Angabe entspricht Automatik)
set lmargin # ohne Angabe entspr auto; dimensilnslose Zahl entspr. Zeichenbreite
set rmargin at screen 0.990
set bmargin at screen 0.180
set tmargin at screen 0.960
# grauer Hintergrund für Testzwecke
# set object rectangle from screen 0,0 to screen 1,1 fillcolor rgb my_black_e0 behind


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir bei UNIX in eine Pipe und sind so beim Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg) 
# Windowsbenutzer, die mit Pipes nicht umgehen könnten, sollten das Kommentar-
# zeichen vor dem  'set output ...' folgenden Befehl entfernen. 
# set output 'Einwohnerentwicklung_von_Jülich.svg' 
set term svg size 800,400 font "Arial,16"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer 
# Einbindung [[Datei:Einwohnerentwicklung_von_Jülich.svg|mini|400px|Text]] noch Schrift/Details 
# erkennen kann. 


# Log10 Skalierung für Y-Achse wählen 
#  set logscale y 10
# Für Formatparam siehe http://gnuplot.sourceforge.net/docs_4.2/node184.html
# Wert für ytics hier mit 10 Überschreiben damit die Mantisse wegfallen kann. 
# Ansonsten müsste sie wie in 'set format y "%.1l*10^{%L}"; set ytics 5' angegeben 
# werden was ungerade Werte ergibt. 
# xrange muss größer Null beginnen. Kann oben mit my_yrange_min auf 10, 100, 1000 ... 
# gesetzt werden oder hier auskommentieren. 
#  set format y "  10^{%L}"; set ytics 10; set mytics 10; set yrange [100:100000]


# Abkürzungen hinter dem Plot-Befehl:
#       u : using
#       w : with
#      lc : linecolor
#      lt : linetype 
#      lw : linewidth
#      pt : pointtype  
#      ps : pointsize
#      lp : linespoints
#       p : points
#       t : title
#     not : notitle
# filledc : filledcurves (Bsp.: File:Einwohnerentwicklung von Wanne-Eickel.svg)
#     rgb : RedGreenBlue
#      ax ; axes (bei der Plotanweisung meist x1y1)

# Daten per Here-Document
# (siehe Abschntt 'Inline data and datablocks' in
# http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
$my_HD_1 << EndOfData_1
# bei 'plot' mit '$my_HD_1 use 1:2 with ...' einbinden
...
EndOfData_1


# Jede Kurve wird zweimal gezeichnet. Beim ersten mal mit etwas Transparenz
# damit es heller wird. Beim zweiten mal werden die Punkt dunkel
# nachgezeichnet. Dadurch sollte der Betrachter besser erkennen können, wo
# Messpunkte fehlen. 
#
# Erzeugen der Ausgabe 
plot \
  my_data  u 1:2 ax x1y1 w lp lc rgb my_darkblue_40  lt 1 lw 1.5 pt 7 ps 0.22   t 'Einw. Entw.',\
  my_data  u 1:2 ax x1y1 w  p lc rgb my_darkblue_00  lt 1 lw 1.5 pt 7 ps 0.22 not              ,\
# $my_HD_1 u 1:2 ax x1y1 w lp lc rgb my_darkred_40   lt 1 lw 1.5 pt 7 ps 0.22   t 'Einw. Entw.',\
# $my_HD_1 u 1:2 ax x1y1 w  p lc rgb my_darkred_00   lt 1 lw 1.5 pt 7 ps 0.22 not              ,\

Daten

[edit]

Die folgenden Daten bitte in eine Textdatei unter dem Namen "Einwohnerentwicklung_von_Jülich.dat" abspeichern und ins gleiche Verzeichnis wie das GnuPlot-Script ablegen.

Update der Daten und Überschreiben der Grafik ausdrücklich erwünscht (bei Problemen beim Erstellen einer neuen Grafik unter de:Benutzer Diskussion:Summer ... hier! oder de:Wikipedia:Grafikwerkstatt nachfragen).

Vor Änderungen der Struktur dieses Abschnitts bitte beachten, das die Daten zur Wartung anderer Grafiken benutzt werden. Dies sind Dateien, die möglicherweise die Daten dieses Abschnitts verwenden.

#
# Quelle: 
# https://de.wikipedia.org/wiki/Einwohnerentwicklung_von_J%C3%BClich#Bev%C3%B6lkerungsentwicklung_von_J%C3%BClich
#
#
30.06.300;1500
30.06.1533;1300
30.06.1647;1300
30.06.1719;1355
30.06.1725;1495
30.06.1735;1520
30.06.1745;1775
30.06.1755;1890
30.06.1775;1925
30.06.1795;2025
30.06.1799;2126
30.06.1802;2429
30.06.1805;2429
30.06.1812;2796
30.06.1814;1624
30.06.1860;3119
30.06.1867;2659
30.06.1871;3335
01.12.1880;3731
01.12.1885;3992
30.06.1890;3952
01.12.1895;4521
30.06.1900;4964
01.12.1905;5486
01.12.1910;6109
30.06.1913;6834
30.06.1920;7688
30.06.1921;7752
30.06.1922;7854
30.06.1923;8394
30.06.1924;8431
30.06.1925;8596
30.06.1926;8712
30.06.1927;8997
30.06.1928;9129
30.06.1929;9443
30.06.1930;9664
30.06.1931;10051
30.06.1932;10945
30.06.1933;10151
30.06.1934;10595
30.06.1935;10786
30.06.1936;10812
30.06.1937;11262
30.06.1939;12000
30.04.1945;100
31.05.1945;842
30.06.1945;1270
30.09.1945;3903
31.10.1945;5905
30.11.1945;6121
31.12.1945;6386
31.12.1946;6916
31.12.1947;7526
31.12.1948;8120
31.12.1949;8800
31.12.1950;9482
31.12.1951;10182
31.12.1952;10703
31.12.1953;11536
31.12.1954;11939
31.12.1955;12492
31.12.1956;13007
31.12.1957;13461
31.12.1958;13691
31.12.1959;14008
31.12.1960;14339
06.06.1961;14687
31.12.1961;14958
31.12.1962;15306
31.12.1963;16126
31.12.1964;17369
31.12.1965;18209
31.12.1966;18939
31.12.1967;19315
31.12.1968;19648
31.12.1969;20076
27.05.1970;19439
31.12.1970;20778
31.12.1971;20333
31.12.1972;32084
31.12.1973;32028
31.12.1974;31896
31.12.1975;31564
31.12.1976;31221
31.12.1977;31009
31.12.1978;30652
31.12.1979;30495
31.12.1980;30433
31.12.1981;30521
31.12.1982;30428
31.12.1983;30275
31.12.1984;30192
31.12.1985;30150
31.12.1986;30156
31.12.1987;30515
31.12.1988;30464
31.12.1989;30751
31.12.1990;31149
31.12.1991;31622
31.12.1992;31886
31.12.1993;31780
31.12.1994;31762
31.12.1995;32061
31.12.1996;32423
31.12.2000;33434
31.12.2001;33951
31.12.2002;34289
31.12.2003;34085
31.12.2004;34022
31.12.2005;33811
31.12.2006;33772
31.12.2007;33565
31.12.2008;33786
30.06.2009;33524
31.12.2009;33100
31.12.2010;33133
31.12.2011;33132
30.06.2012;33081
31.12.2012;33044
30.03.2013;33268
30.06.2013;33214
31.07.2015;33536
31.12.2015;33903
31.12.2016;32454
31.12.2017;32505 
# EOF

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current23:59, 8 May 2019Thumbnail for version as of 23:59, 8 May 2019800 × 400 (78 KB)Summer ... hier! (talk | contribs)Zeitintervall begann bei falschen Wert
23:32, 8 May 2019Thumbnail for version as of 23:32, 8 May 2019800 × 400 (66 KB)Summer ... hier! (talk | contribs)+2017
11:19, 6 May 2018Thumbnail for version as of 11:19, 6 May 2018800 × 400 (86 KB)Summer ... hier! (talk | contribs){{Information |Description = {{de|Einwohnerentwicklung von Jülich}} |Source = {{own}} |Author = ~~~~ |Date = }} == {{int:license-header}} == {{self|Cc-zero}} == Gnuplot script to generate this plot == {{gnuplot}}{{ValidSVG}}<!--{{Created with Gnuplot | v }}--> <source lang="gnuplot"> #!/usr/bin/gnuplot # gnuplot # Variablen - die wichtigsten Paramter dieser Grafik: # (in der Regel wird es reichen für eine neue Grafik diese Werte zu ändern) my_data ...

There are no pages that use this file.

File usage on other wikis

The following other wikis use this file:

Metadata