File:Einwohnerentwicklung von Bremen.svg
![File:Einwohnerentwicklung von Bremen.svg](https://upload.wikimedia.org/wikipedia/commons/thumb/c/cb/Einwohnerentwicklung_von_Bremen.svg/800px-Einwohnerentwicklung_von_Bremen.svg.png?20190719223515)
Original file (SVG file, nominally 800 × 400 pixels, file size: 88 KB)
Captions
Captions
Summary
[edit]DescriptionEinwohnerentwicklung von Bremen.svg |
Deutsch: Einwohnerentwicklung von Bremen |
Source | Own work |
Author | Summer ... hier! (talk) 10:52, 24 January 2018 (UTC) |
Licensing
[edit]![]() ![]() |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Gnuplot script to generate this plot
[edit]#!/usr/bin/gnuplot
# gnuplot
### Variablen - die wichtigsten Paramter dieser Grafik:
# (in der Regel wird es reichen für eine neue Grafik diese Werte zu ändern)
my_data = 'Einwohnerentwicklung_von_Bremen.dat'
my_xrange_min = '01.01.1340'
my_xrange_max = '31.12.2018'
my_xtics_years = '100'
my_mxtics = '5'
my_yrange_min = '-1' # bei '-1' wird der erste
# Achenstrich unter Null berechnet
my_yrange_max = '*' # hier ist '*' erlaubt und sinnvoll
my_ytics = '100000'
my_ymtics = '5'
ist_gemeinde = '1' # 1 für ja, 0 für nein
# Falls ja, werden Marker für Grossstadt
# und Mio.Stadt gesetzt
WW1 = '0.90' # horiz. Pos. des WW1 Schriftzugs
WW2 = '0.90' # horiz. Pos. des WW2 Schriftzugs
DDR = '0.00' # horiz. Pos. des Deut.Einheit-Schriftzugs
# (0 entspr. keiner Ausgabe)
### Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y" # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator
set datafile commentschars "#" # Kommentarzeichen
stats my_data u (strptime("%d.%m.%Y",strcol(1))) nooutput
my_diff = (STATS_max - STATS_min) / (60*60*24*365.25)
print ' -----Stats-(Timestamp)----------------------'
print ' Erster Wert der Datendatei: ', strftime("%d.%m.%Y", STATS_min)
print ' Letzter Wert der Datendatei: ', strftime("%d.%m.%Y", STATS_max)
print ' Diff in Jahren: ', my_diff
print ' --------------------------------------------'
# Anmerk.: die ausgegebenen Timestamps können in einer Shell bequem mit
# 'date -d @[Wert]' in humanleseriches Format gewandelt werden
### Allgemeines zur Ausgabe
set key vertical maxrows 6 # Max Anzahl Zeilen
# set key center top # Legende links oben (mit rel. Angaben)
set key at graph 0.05,0.95 # Ĺegende weit links-oben (mit Angaben bez. auf Graph)
set key left top # Punkt der Legendenbox an dem sie Ausgerichtet wird
set key nobox # kein Rahmen (zu Testzwecken box setzen!)
set key noopaque # Transparenz
set key samplen 2 # Breite der Linenbeispiele
unset key # direkt vorher gesetzte Werte aufgehoben; ggf.
# auskommentieren, dann wird die Legende gesetzt!
set style data lines # wird bei 'plot' überschrieben
set style fill transparent solid 0.4 # wird ebenfalls bei 'plot' überschrieben
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set grid # Gitterlinien verwenden
# Gitterlinien per Hand setzen falls gewünscht
set style line 1 linetype rgb '#4F4F4F' linewidth 0.5 dashtype 2 # Def. Major-grid
set style line 2 linetype rgb '#9F9F9F' linewidth 0.5 dashtype 3 # def. Minor-grid
set grid xtics mxtics # eventuell noxtics und nomxtics
set grid ytics mytics # eventuell noytics und nomytics
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle für Major u. Minor
#show grid # Kontrollausgabe auf der Konsole
### Farben - nummerische Equavalente zu Namen nach:
# https://www2.uni-hamburg.de/Wiss/FB/15/Sustainability/schneider/gnuplot/colors.htm
# Die beiden Ziffen am Ende der Variablen geben opacity/transparenz an
#
my_darkred_00 = '#008B0000'; my_darkred_20 = '#208B0000';
my_darkred_40 = '#408B0000'; my_darkred_60 = '#608B0000';
my_darkred_80 = '#808B0000'; my_darkred_a0 = '#a08B0000';
my_darkred_c0 = '#c08B0000'; my_darkred_e0 = '#e08B0000';
#
my_darkgreen_00 = '#00006400'; my_darkgreen_20 = '#20006400';
my_darkgreen_40 = '#40006400'; my_darkgreen_60 = '#60006400';
my_darkgreen_80 = '#80006400'; my_darkgreen_a0 = '#a0006400';
my_darkgreen_c0 = '#c0006400'; my_darkgreen_e0 = '#e0006400';
#
my_darkblue_00 = '#0000008B'; my_darkblue_20 = '#2000008B';
my_darkblue_40 = '#4000008B'; my_darkblue_60 = '#6000008B';
my_darkblue_80 = '#8000008B'; my_darkblue_a0 = '#a000008B';
my_darkblue_c0 = '#c000008B'; my_darkblue_e0 = '#e000008B';
#
my_darkmagenta_00 = '#008B008B'; my_darkmagenta_20 = '#208B008B';
my_darkmagenta_40 = '#408B008B'; my_darkmagenta_60 = '#608B008B';
my_darkmagenta_80 = '#808B008B'; my_darkmagenta_a0 = '#a08B008B';
my_darkmagenta_c0 = '#c08B008B'; my_darkmagenta_e0 = '#e08B008B';
#
my_darkorange_00 = '#00FF8C00'; my_darkorange_20 = '#20FF8C00';
my_darkorange_40 = '#40FF8C00'; my_darkorange_60 = '#60FF8C00';
my_darkorange_80 = '#80FF8C00'; my_darkorange_a0 = '#a0FF8C00';
my_darkorange_c0 = '#c0FF8C00'; my_darkorange_e0 = '#e0FF8C00';
#
my_darkturquoise_00 = '#0000CED1'; my_darkturquoise_20 = '#2000CED1';
my_darkturquoise_40 = '#4000CED1'; my_darkturquoise_60 = '#6000CED1';
my_darkturquoise_80 = '#8000CED1'; my_darkturquoise_a0 = '#a000CED1';
my_darkturquoise_c0 = '#c000CED1'; my_darkturquoise_e0 = '#e000CED1';
#
my_black_00 = '#00000000'; my_black_20 = '#20000000';
my_black_40 = '#40000000'; my_black_60 = '#60000000';
my_black_80 = '#80000000'; my_black_a0 = '#a0000000';
my_black_c0 = '#c0000000'; my_black_e0 = '#e0000000';
### Bereiche/Format/etc X-Achse
set xdata time # X-Achse als Zeitachse
set xlabel 'Jahr' # Beschriftung X-Achse
set xlabel offset 0, 0.75 # Schrift etwas höher
set xrange [ my_xrange_min : my_xrange_max]
# Wertebreich der X-Achse
set xtics '01.01.1000', (60*60*24*365.25) * my_xtics_years
# xtics in Sekunden
# der Beginn (Wert vor dem Komma) der X-Einteilung
# kann außerhalb xrange liegen
set xtics offset 0, 0.5 # Beschriftung näher an die X-Achse
set mxtics my_mxtics # Skalenstriche
set xtics nomirror # Nur unten Skalieren
set format x '%3Y' # Beschr.format JJJJ (bei 3 Stellen o. führend 0)
set xtics out # Skal. aussen damit sie nicht von Grafik
# überschr. wird
# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label
# Untere Begrenzung des Bereichs der Y-Achse
# Falls my_yrange_min wird der erste Achsenstrich unterhalb der
# Nulllinie berechnet
if (my_yrange_min == -1 ) my_yrange_min = - my_ytics / my_ymtics
set yrange [ my_yrange_min : ]
# Obere Begrenzung des Bereichs der Y-Achse
# wir Testen ob der Wert der Var. my_yrange_max ein '*' ist und reagieren
# entsprechend weil der '*' sich nicht direkt via Var. setzen lässt.
if ( ( my_yrange_max eq '*' )) set yrange [ : * ]
if (!( my_yrange_max eq '*' )) set yrange [ : my_yrange_max ]
set ytics my_ytics # Anzahl der kleinen Teilstriche
set ytics offset 0.5 # Schrift etwas nach rechts
set ytics nomirror # oben keine Teilstriche
set decimalsign locale "de_DE.utf8" # Stelle Input und Output auf "," um
# set decimalsign ',' würde nur Output umstellen,
set format y "%'.0f" # Ausgabeformat
set mytics my_ymtics # Unterskalierung
set ytics out # Skal. aussen da sie sonst von Grafik
# überschr. wird
### Markierungsbalken für die beiden Weltkriege etc.
# Die set-Befehle ggf. auskommentieren
# Attribute für Markierungsbalken
set style rect fillcolor lt -1 fillstyle solid 0.1 noborder
#
# == Dreißigjähriger Krieg
set obj rect from '23.05.1618', graph 0 to '24.10.1648' , graph 1 back
set label "Dreißigjähriger Krieg" at '30.06.1633', graph 0.8 rotate by +60 center front
# == Siebenjähriger Krieg
# set obj rect from '29.08.1756', graph 0 to '21.09.1762' , graph 1 back
# set label "Siebenjähriger Krieg" at '30.06.1759', graph 0.8 rotate by +60 center front
# == Hamburger Franzosenzeit
# set obj rect from '30.06.1806', graph 0 to '30.06.1814' , graph 1 back
# set label "H. Franzosenzeit" at '01.01.1810', graph 0.3 rotate by +60 center front
# == Befreiungskriege
# set obj rect from '26.02.1813', graph 0 to '20.11.1815' , graph 1 back
# set label "Befreiungskriege" at '30.06.1814', graph 0.8 rotate by +60 center front
# == 1. Weltkrieg
set obj rect from '28.07.1914', graph 0 to '11.11.1918' , graph 1 back
set label "1. Weltkrieg" at '30.06.1916', graph WW1 rotate by +60 center front
# == 2. Weltkrieg
set obj rect from '01.09.1939', graph 0 to '04.05.1945' , graph 1 back
set label "2. Weltkrieg" at '30.06.1942', graph WW2 rotate by +60 center front
# == Dädärä
if (DDR > 0) {
set obj rect from '07.10.1949', graph 0 to '03.10.1990' , graph 1 back
set label "Deut. Teilung" at '01.01.1970', graph DDR rotate by +60 center front
}
### Markierung für Groß- und Millionenstadtgrenze
# wenn oben die Variable 'gemeinde' auf '1' gesetzt wurde setzen wir Maker
if (ist_gemeinde eq '1') {
# je einen Marker (arrow) für 100.000 und 1.000.000
set arrow from my_xrange_min, '100000' to my_xrange_max, '100000' nohead lc rgb '#B0FF0000' back
set arrow from my_xrange_min, '1000000' to my_xrange_max, '1000000' nohead lc rgb '#B0FF0000' back
}
### Einzelwerte (Beispiel)
# set label 1 'Bsp. Text 1' at '25.05.1987', 5000 point pointtype 3 pointsize 0.8
# set label 2 'Bsp. Text 2' at '09.05.2011', 10000 point pointtype 3 pointsize 0.8
### Außenränder (keine Angabe entspricht Automatik)
# keine Angabe hinter Xmargin entspr auto
# zur Positionierung siehe 'Coordinates' in:
# http://gnuplot.sourceforge.net/docs_4.2/node49.html#448
set lmargin
set rmargin at screen 0.990
set bmargin at screen 0.175
set tmargin at screen 0.960
# grauer Hintergrund für Testzwecke
# set object rectangle from screen 0,0 to screen 1,1 fillcolor rgb my_black_e0 behind
### Dateiausgabe definieren
# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir bei UNIX in eine Pipe und sind so beim Namen der
# Ausgabedatei flexibel (Aufruf: Einwohnerentwicklung_von_Bremen.gpl > Einwohnerentwicklung_von_Bremen.svg)
# Windowsbenutzer, die mit Pipes nicht umgehen könnten, sollten das Kommentar-
# zeichen vor dem 'set output ...' folgenden Befehl entfernen.
# set output 'Einwohnerentwicklung_von_Bremen.svg'
set term svg size 800,400 font "Arial,16"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer
# Einbindung [[Datei:Einwohnerentwicklung_von_Bremen.svg|mini|400px|Text]] noch Schrift/Details
# erkennen kann.
### Log10 Skalierung für Y-Achse wählen
# Für Formatparam siehe http://gnuplot.sourceforge.net/docs_4.2/node184.html
# Wert für ytics hier mit 10 Überschreiben damit die Mantisse wegfallen kann.
# Ansonsten müsste sie wie in 'set format y "%.1l*10^{%L}"; set ytics 5' angegeben
# werden was ungerade Werte ergibt.
# xrange muss größer Null beginnen. Kann oben mit my_yrange_min auf 10, 100, 1000 ...
# gesetzt werden oder hier auskommentieren.
# set logscale y 10; set format y " 10^{%L}"; set ytics 10; set mytics 10;
# set lmargin 5 # ev. bei 'Schwestergrafik' gleichen fixen Wert setzen.
# set yrange [ 100 : 1000000 ] # yrange manuell Anpassen!!!
### Abkürzungen hinter dem Plot-Befehl:
# u : using
# w : with
# lc : linecolor
# lt : linetype
# lw : linewidth
# pt : pointtype
# ps : pointsize
# lp : linespoints
# p : points
# t : title
# not : notitle
# filledc : filledcurves (Bsp.: File:Einwohnerentwicklung von Wanne-Eickel.svg)
# rgb : RedGreenBlue
# ax ; axes (bei der Plotanweisung meist x1y1)
### Daten per Here-Document
# (siehe Abschntt 'Inline data and datablocks' in
# http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
$my_HD_1 << EndOfData_1
# bei 'plot' mit '$my_HD_1 use 1:2 with ...' einbinden
...
EndOfData_1
### Plot
# Jede Kurve wird zweimal gezeichnet. Beim ersten mal mit etwas Transparenz
# damit es heller wird. Beim zweiten mal werden die Punkt dunkel
# nachgezeichnet. Dadurch sollte der Betrachter besser erkennen können, wo
# Messpunkte fehlen.
#
# Erzeugen der Ausgabe
plot \
my_data u 1:2 ax x1y1 w lp lc rgb my_darkblue_40 lt 1 lw 1.5 pt 7 ps 0.22 t 'Einw. Entw.',\
my_data u 1:2 ax x1y1 w p lc rgb my_darkblue_00 lt 1 lw 1.5 pt 7 ps 0.22 not ,\
# $my_HD_1 u 1:2 ax x1y1 w lp lc rgb my_darkred_40 lt 1 lw 1.5 pt 7 ps 0.22 t 'Einw. Entw.',\
# $my_HD_1 u 1:2 ax x1y1 w p lc rgb my_darkred_00 lt 1 lw 1.5 pt 7 ps 0.22 not ,\
Daten
[edit]Die folgenden Daten bitte in eine Textdatei unter dem Namen "Einwohnerentwicklung_von_Bremen.dat" abspeichern und ins gleiche Verzeichnis wie das GnuPlot-Script ablegen.
Update der Daten und Überschreiben der Grafik ausdrücklich erwünscht (bei Problemen beim Erstellen einer neuen Grafik unter de:Benutzer Diskussion:Summer ... hier! oder de:Wikipedia:Grafikwerkstatt nachfragen).
Vor Änderungen der Struktur dieses Abschnitts bitte beachten, das die Daten zur Wartung anderer Grafiken benutzt werden. Dies sind Dateien, die möglicherweise die Daten dieses Abschnitts verwenden.
#
# Quelle:
# https://de.wikipedia.org/wiki/Einwohnerentwicklung_von_Bremen#Einwohnerentwicklung
#
30.06.1350;10000
30.06.1352;5000
30.06.1550;15000
30.06.1650;25000
30.06.1744;28000
30.06.1790;30000
30.06.1807;36041
30.06.1811;36630
30.06.1812;35392
30.06.1818;37029
#
30.06.1823;39493
30.06.1831;44286
30.06.1842;49700
03.12.1845;53156
03.12.1849;53478
03.12.1852;57055
03.12.1855;60087
16.02.1862;66938
03.12.1864;70692
03.12.1867;74574
#
#
#
#
01.12.1871;82969
31.12.1874;88980
01.12.1875;102499
01.12.1880;112453
01.12.1885;118395
01.12.1890;125684
02.12.1895;141133
01.12.1900;161184
31.12.1901;165864
31.12.1902;192352
31.12.1903;199620
31.12.1904;206928
01.12.1905;214953
31.12.1906;216624
31.12.1907;226725
31.12.1908;233826
31.12.1909;240927
#
01.12.1910;247437
31.12.1911;250526
31.12.1912;259407
31.12.1913;265711
01.12.1916;222895
05.12.1917;234369
08.10.1919;257923
31.12.1919;262767
31.12.1920;266311
31.12.1921;282622
31.12.1922;284027
31.12.1923;277652
31.12.1924;279171
16.06.1925;294966
31.12.1925;295585
31.12.1926;296937
31.12.1927;299988
#
31.12.1928;302949
31.12.1929;304490
31.12.1930;306471
31.12.1931;309352
31.12.1932;313993
16.06.1933;323331
31.12.1933;324189
31.12.1934;326113
31.12.1935;331266
31.12.1936;336801
31.12.1937;341124
31.12.1938;353100
17.05.1939;354109
31.12.1939;431800
31.12.1940;441800
#
#
#
#
31.07.1945;289221
31.12.1945;366427
29.10.1946;385266
31.12.1947;405624
13.09.1950;444549
31.12.1951;463049
31.12.1952;472962
31.12.1953;483539
25.09.1956;507952
06.06.1961;564517
31.12.1961;569862
31.12.1962;575220
31.12.1963;580956
31.12.1964;587941
#
31.12.1965;596100
31.12.1966;601884
31.12.1967;603600
31.12.1968;604997
31.12.1969;607184
27.05.1970;582277
31.12.1970;592533
31.12.1971;594591
31.12.1972;589825
31.12.1973;584265
31.12.1974;579430
31.12.1975;572969
31.12.1976;568217
31.12.1977;562664
#
31.12.1978;558942
31.12.1979;556128
31.12.1980;555118
31.12.1981;553261
31.12.1982;547619
31.12.1983;540442
31.12.1984;530520
31.12.1985;526377
31.12.1986;521976
25.05.1987;533455
31.12.1987;532686
31.12.1988;535058
31.12.1989;544327
#
#
#
#
31.12.1990;551219
31.12.1991;552746
31.12.1992;554377
31.12.1993;551604
31.12.1994;549182
31.12.1995;549357
31.12.1996;548826
31.12.1997;546968
31.12.1998;543279
31.12.1999;540330
#
31.12.2000;539403
31.12.2001;540834
31.12.2002;542987
31.12.2003;544853
31.12.2004;545932
31.12.2005;546852
31.12.2006;547934
31.12.2007;547769
31.12.2008;547360
31.12.2009;547685
#
31.12.2010;547340
09.05.2011;542707
31.12.2011;544043
31.12.2012;546451
31.12.2013;548547
31.12.2014;551767
31.12.2015;557464
31.12.2016;565719
31.12.2017;568006
31.12.2018;569352
# EOF
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 22:35, 19 July 2019 | ![]() | 800 × 400 (88 KB) | Summer ... hier! (talk | contribs) | +Wert 2018 |
00:11, 2 February 2019 | ![]() | 800 × 400 (87 KB) | Summer ... hier! (talk | contribs) | +Wert 2017 | |
22:02, 15 March 2018 | ![]() | 800 × 400 (86 KB) | Summer ... hier! (talk | contribs) | +Wert 2016 | |
10:52, 24 January 2018 | ![]() | 800 × 400 (37 KB) | Summer ... hier! (talk | contribs) | {{Information |Description = {{de|Einwohnerentwicklung von Bremen}} |Source = {{own}} |Author = ~~~~ |Date = }} == {{int:license-header}} == {{self|Cc-zero}} == Gnuplot script to generate this plot == {{gnuplot}}{{ValidS... |
You cannot overwrite this file.
File usage on Commons
There are no pages that use this file.
File usage on other wikis
The following other wikis use this file:
- Usage on de.wikipedia.org
Metadata
This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.
Short title | Gnuplot |
---|---|
Image title | Produced by GNUPLOT 5.0 patchlevel 3 |
Width | 800 |
Height | 400 |