File:Dark Field Microscopy.gif

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Original file (723 × 723 pixels, file size: 7.47 MB, MIME type: image/gif, looped, 70 frames, 7.0 s)

Captions

Captions

If you illuminate a surface from the high refractive index side at a high enough angle, no light will be transmitted due to total internal reflection. But if there is something on the surface, it will scatter light, which you can measure.

Summary

[edit]
Description
English: If you illuminate a surface from the high refractive index side at a high enough angle, no light will be transmitted (total internal reflection). But if there is something on the surface, it will scatter light (that you can measure).

Small particles of low refractive index, will produce effectively spherical waves, which can thus be directly imaged against a very dark background.

Plotting the modulus of the field instead of the intensity to make the effect more visible. The refractive indices are also unrealistically high, to make the visualization clearer.
Date
Source https://twitter.com/j_bertolotti/status/1410181128003231746
Author Jacopo Bertolotti
Permission
(Reusing this file)		 https://twitter.com/j_bertolotti/status/1030470604418428929

Mathematica 12.0 code

[edit]
\[Sigma] = 5.; \[Lambda]0 = 2.; k0 = N[(2 \[Pi])/\[Lambda]0];
\[Delta] = \[Lambda]0/20; \[CapitalDelta] = 40*\[Lambda]0;
\[Phi]in = Table[0, {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
dim = Dimensions[\[Phi]in][[1]];
d = \[Lambda]0/2; (*typical scale of the absorbing layer*)
Ren = Table[ If[y < 0, 3, 1], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
Imn = Table[10 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) +E^((y - \[CapitalDelta]/2)/d)), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)

n = Ren + I Imn;
M = L + DiagonalMatrix[ SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
sinstep[t_] := Sin[\[Pi]/2 t]^2;
sourcef[x_, y_, t_] := E^(-((x + (\[CapitalDelta]/4)*sinstep[t] )^2/(2 \[Sigma]^2))) E^(I 3.5*sinstep[t] x) E^(-((y + \[CapitalDelta]/2)^2/(2 (\[Lambda]0/2)^2))) E^(I k0 y);
frames1 = Table[
   \[Phi]in = Table[Chop[sourcef[x, y, t] ], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
   b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
   \[Phi]s = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
   ImageAdd[
    ArrayPlot[ Transpose[((Abs[\[Phi]in + \[Phi]s])[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]/Max[(Abs[\[Phi]in + \[Phi]s])[[(10 d)/\[Delta] ;; (-10 d)/\[Delta], (10 d)/\[Delta] ;; (-10 d)/\[Delta]]]])^1], ColorFunction -> "AvocadoColors" , DataReversed -> True, Frame -> False, PlotRange -> {0, 1}],
    ArrayPlot[Transpose@Re[(n - 1)/50] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel, Frame -> False]
    ](*Plot everything*)
   , {t, 0, 1, 1/(20 - 1)}];

stopstep[t_] := t^4;
frames2 = Table[
   Ren1 = Ren + 10*RotateRight[DiskMatrix[3, dim], {0, 3 + Round[300*stopstep[t]]}];
   n = Ren1 + I Imn;
   M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
   \[Phi]in = Table[Chop[sourcef[x, y, 1] ], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
   b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
   \[Phi]s = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
   ImageAdd[
    ArrayPlot[ Transpose[((Abs[\[Phi]in + \[Phi]s])[[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]/Max[(Abs[\[Phi]in + \[Phi]s])[[(10 d)/\[Delta] ;; (-10 d)/\[Delta], (10 d)/\[Delta] ;; (-10 d)/\[Delta]]]])^1], ColorFunction -> "AvocadoColors" , DataReversed -> True, Frame -> False, PlotRange -> {0, 1}],
    ArrayPlot[Transpose@Re[(n - 1)/50] , DataReversed -> True , ColorFunctionScaling -> False, ColorFunction -> GrayLevel, Frame -> False]
    ](*Plot everything*)
   , {t, 0, 1, 1/(40 - 1)}];

ListAnimate[Join[frames1(*,Table[frames1[[-1]],5]*), Reverse@frames2, Table[frames2[[1]], 10]] ]

Licensing

[edit]
I, the copyright holder of this work, hereby publish it under the following license:
Creative Commons CC-Zero This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current08:36, 1 July 2021Thumbnail for version as of 08:36, 1 July 2021723 × 723 (7.47 MB)Berto (talk | contribs)Uploaded own work with UploadWizard

You cannot overwrite this file.

There are no pages that use this file.

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Dark_Field_Microscopy.gif&oldid=885565796"